(VBScript) S3 Upload String using AWS Signature Version 2

Example to upload the contents of a string to the Amazon S3 service, using the older AWS Signature Version 2.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Demonstrates how to use older AWS S3 Signature Version 2 for uploading the contents
' of a string variable to an object in a bucket.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
bTls = 1
port = 443
bAutoReconnect = 1
' The file is uploaded to the bucket named "chilkat100", which becomes part of the domain:
success = rest.Connect("chilkat100.s3.amazonaws.com",port,bTls,bAutoReconnect)

' ----------------------------------------------------------------------------
' Important: For buckets created in regions outside us-east-1,
' there are three important changes that need to be made.
' See Working with S3 Buckets in Non-us-east-1 Regions for the details.
' ----------------------------------------------------------------------------

' Provide AWS credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"

' For AWS Signature Version 2, the following two properties need to be set:
authAws.SignatureVersion = 2
' See http://docs.aws.amazon.com/AmazonS3/latest/dev/RESTAuthentication.html#ConstructingTheCanonicalizedResourceElement
' The bucket is "chilkat100", and the uriPath is "/hamlet_play.xml", which must match
' the URI path passed to the FullRequestString method below.
authAws.CanonicalizedResourceV2 = "/chilkat100/hamlet_play.xml"

success = rest.SetAuthAws(authAws)

' Load a text file into memory.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")
fileContents = fac.ReadEntireTextFile("qa_data/xml/hamlet.xml","utf-8")
If (fac.LastMethodSuccess <> 1) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If

' To send the file in gzip or deflate compressed format, set the Content-Encoding request
' header to "gzip" or "deflate".  (this is optional)
success = rest.AddHeader("Content-Encoding","gzip")

' Indicate the Content-Type of our upload.  (This is optional)
success = rest.AddHeader("Content-Type","text/xml")

' We can add an "Expect: 100-continue" header so that if the request is rejected
' by the server immediately after receiving the request header, it can respond
' and the client (Chilkat) can avoid sending the file data.
' (this is optional)
success = rest.AddHeader("Expect","100-continue")

' Upload the file to Amazon S3.
responseBodyStr = rest.FullRequestString("PUT","/hamlet_play.xml",fileContents)
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Did we get a 200 response indicating success?
statusCode = rest.ResponseStatusCode
If (statusCode <> 200) Then
    outFile.WriteLine("Error response: " & responseBodyStr)
    outFile.WriteLine("Status code: " & statusCode & ", Status text: " & rest.ResponseStatusText)
    WScript.Quit
End If

outFile.WriteLine("File successfully uploaded.")

outFile.Close