(VBScript) S3 Put Bucket Policy

Demonstrates how to add or replace a policy on a bucket. The following information is quoted from the AWS REST API reference documentation at PUT Bucket Policy

This implementation of the PUT operation uses the policy subresource to add to or replace a policy on a bucket. If the bucket already has a policy, the one in this request completely replaces it. To perform this operation, you must be the bucket owner. If you are not the bucket owner but have PutBucketPolicy permissions on the bucket, Amazon S3 returns a 405 Method Not Allowed. In all other cases for a PUT bucket policy request that is not from the bucket owner, Amazon S3 returns 403 Access Denied. There are restrictions about who can create bucket policies and which objects in a bucket they can apply to. For more information, go to Using Bucket Policies.

Important: This example requires Chilkat v9.5.0.66 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Important: This example requires Chilkat v9.5.0.66 or greater.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server in the desired region.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("s3-us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"

' This particular bucket is in the Oregon region, as opposed to the US Standard,
' therefore the Region must be set appropriately.
' Also note that we connected to "s3-us-west-2.amazonaws.com".
authAws.Region = "us-west-2"

success = rest.SetAuthAws(authAws)

' Note: The above REST connection and setup of the AWS credentials
' can be done once.  After connecting, any number of REST calls can be made.
' The "auto reconnect" property passed to rest.Connect indicates that if
' the connection is lost, a REST method call will automatically reconnect
' if needed.
' --------------------------------------------------------------------------

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkat.ocean".
' Note that the Host header should use "bucketName.s3.amazonaws.com", not "bucketName.s3-us-west-2.amazonaws.com"
rest.Host = "chilkat.ocean.s3.amazonaws.com"

' Build the S3 JSON Policy to be sent in the request:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("Version","2012-10-17")
success = json.UpdateString("Statement[0].Action[0]","s3:GetObject")
success = json.UpdateString("Statement[0].Effect","Allow")
success = json.UpdateString("Statement[0].Resource","arn:aws:s3:::chilkat.ocean/")
success = json.UpdateString("Statement[0].Principal","*")

' The JSON Policy constructed by the above lines of code is:
' (The bucket name is "chilkat.ocean")

' 	{ 
' 	  "Version": "2012-10-17",
' 	  "Statement": [
' 	    { 
' 	      "Action": [
' 	        "s3:GetObject"
' 	      ],
' 	      "Effect": "Allow",
' 	      "Resource": "arn:aws:s3:::chilkat.ocean/",
' 	      "Principal": "*"
' 	    }
' 	  ]
' 	}

' Add or replace the policy on the bucket.
responseJsonStr = rest.FullRequestString("PUT","/?policy",json.Emit())
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the S3 Storage service will respond with a 200 or 204 response code,
' with an XML body.  
If ((rest.ResponseStatusCode <> 200) And (rest.ResponseStatusCode <> 204)) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & responseJsonStr)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
End If

outFile.WriteLine("Success.")

' A successful response has no response body..
' (The Amazon documentation indicates a 204 response, but in our testing we receive a 200 response..)

' 	HTTP/1.1 204 No Content  
' 	x-amz-id-2: Uuag1LuByR5Onimru9SAMPLEAtRPfTaOFg==  
' 	x-amz-request-id: 656c76696e6727732SAMPLE7374  
' 	Date: Tue, 04 Apr 2010 20:34:56 GMT  
' 	Connection: keep-alive  
' 	Server: AmazonS3  

outFile.Close