(VBScript) Initiate Multipart S3 Upload

Initiates an Amazon AWS multipart S3 upload.

The following is quoted from the Amazon Simple Storage Service Documentation:

"The Multipart upload API enables you to upload large objects in parts. You can use this API to upload new large objects or make a copy of an existing object (see Operations on Objects).

Multipart uploading is a three-step process: You initiate the upload, you upload the object parts, and after you have uploaded all the parts, you complete the multipart upload. Upon receiving the complete multipart upload request, Amazon S3 constructs the object from the uploaded parts, and you can then access the object just as you would any other object in your bucket.

You can list of all your in-progress multipart uploads or get a list of the parts that you have uploaded for a specific multipart upload. Each of these operations is explained in this section.

Multipart Upload Initiation

When you send a request to initiate a multipart upload, Amazon S3 returns a response with an upload ID, which is a unique identifier for your multipart upload. You must include this upload ID whenever you upload parts, list the parts, complete an upload, or abort an upload. If you want to provide any metadata describing the object being uploaded, you must provide it in the request to initiate multipart upload."

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Other S3 Multipart Upload Examples:
' S3 Upload Parts
' Complete Multipart Upload
' Abort Multipart Upload
' List Parts

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("s3.amazonaws.com",port,bTls,bAutoReconnect)

' ----------------------------------------------------------------------------
' Important: For buckets created in regions outside us-east-1,
' there are three important changes that need to be made.
' See Working with S3 Buckets in Non-us-east-1 Regions for the details.
' ----------------------------------------------------------------------------

' Provide AWS credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"

success = rest.SetAuthAws(authAws)

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkat100".
rest.Host = "chilkat100.s3.amazonaws.com"

' The local file path (on our local system) to upload.
fileToUploadPath = "s3_multipart_uploads/somethingBig.zip"

' The HTTP request to initiate a multipart upload is a POST with no body content..
' This is the tricky part: We would be tempted to pass "/somethingBig.zip?uploads"
' in the 2nd argument to FullRequestNoBody.  However, we must pass only the path without query
' params.  The "uploads" query param must be added via AddQueryParam.  This allows it to be included
' in the AWS signature calculation for authentication.
success = rest.AddQueryParam("uploads","")
responseXml = rest.FullRequestNoBody("POST","/somethingBig.zip")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the S3 Storage service will respond with a 200 response code,
' with an XML body.  
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & responseXml)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
End If

' See http://docs.aws.amazon.com/AmazonS3/latest/API/mpUploadInitiate.html 
' for a sample of the XML response.
outFile.WriteLine(responseXml)
outFile.WriteLine("----")

' Save the XML response to a file, and show the UploadId..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseXml)
success = xml.SaveXml("s3_multipart_uploads/initiate.xml")

outFile.WriteLine("UploadId = " & xml.GetChildContent("UploadId"))
outFile.WriteLine("Multipart upload initiated.")

outFile.Close