(VBScript) Verfies an RSA Signature

See more Apple Keychain Examples

Verifies an RSA signature against the original data.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' The following data was signed by the following example:
' RSA Sign using a Private Key on a USB Token or Smartcard
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")

For i = 0 To 100
    success = bd.AppendEncoded("000102030405060708090A0B0C0D0E0F","hex")
Next

' Load the signature
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdSig = CreateObject("Chilkat.BinData")
success = bdSig.LoadFile("rsaSignatures/test1.sig")
If (success = 0) Then
    outFile.WriteLine("Failed to load the RSA signature")
    WScript.Quit
End If

' Get the public key to be used for signature verification.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PublicKey")
set pubKey = CreateObject("Chilkat.PublicKey")
success = pubKey.LoadFromFile("rsaKeys/chilkat-rsa-2048.pem")
If (success = 0) Then
    outFile.WriteLine(pubKey.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = CreateObject("Chilkat.Rsa")
success = rsa.ImportPublicKeyObj(pubKey)

' Verify the hash of the data against the signature.
' We pass in the original data.  Internally, the hash is generated
' and used to validate the signature.
' Validating the RSA signature means two things:  
' (1) the original data is exactly what was signed, and 
' (2) it was signed by the owner of the RSA private key.
success = rsa.VerifyBd(bd,"sha256",bdSig)

If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    outFile.WriteLine("Signature invalid.")
Else
    outFile.WriteLine("Signature valid.")
End If


outFile.Close