VBScript Requires Chilkat v11.0.0+

RSA Signature SHA256withRSA, iso-8859-1, base64

See more RSA Examples

RSA sign the iso-8859-1 byte representation of a string with SHA256withRSA, and return the signature in the base64 encoding. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  This example will duplicate the following Java code:
'  
'  Signature sign = Signature.getInstance("SHA256withRSA");
'  sign.initSign(privateKey);
'  sign.update(original.getBytes(Charset.forName("ISO-8859-1")));
'  
'  ...
'  byte[] resultado = sign.sign();
'  sello = encodeByteArrayToBase64(resultado);
'  

'  Load an RSA private key for signing.
'  You can load any format file.  This example loads a .pem, but you can provide path to any type of file holding a private key.
set privKey = CreateObject("Chilkat.PrivateKey")
success = privKey.LoadAnyFormatFile("qa_data/pem/rsa_passwd.pem","passwd")
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

set rsa = CreateObject("Chilkat.Rsa")
success = rsa.UsePrivateKey(privKey)

originalData = "This is the string to be hashed an RSA signed."

'  Indicate that we want the iso-8859-1 byte representation of the string to be signed
rsa.Charset = "iso-8859-1"

'  We want the RSA signature in base64 format
rsa.EncodingMode = "base64"

sigBase64 = rsa.SignStringENC(originalData,"sha256")
outFile.WriteLine(sigBase64)

outFile.Close