(VBScript) RSA Sign String using Private Key of Certificate Type A3 (smart card / token)

Demonstrates RSA signing a string using the private key of a certificate type A3 (smart card, token).

Note: This is a Windows-only example.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' First get the A3 certificate that was installed on the Windows system.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CertStore")
set certStore = CreateObject("Chilkat.CertStore")

thumbprint = "12c1dd8015f3f03f7b1fa619dc24e2493ca8b4b2"

' This is specific to Windows because it is opening the Windows Current-User certificate store.
bReadOnly = 1
success = certStore.OpenCurrentUserStore(bReadOnly)
If (success <> 1) Then
    outFile.WriteLine(certStore.LastErrorText)
    WScript.Quit
End If

' Find the certificate with the desired thumbprint
' (There are many ways to locate a certificate.  This example chooses to find by thumbprint.)
' cert is a Chilkat.Cert
Set cert = certStore.FindCertBySha1Thumbprint(thumbprint)
If (certStore.LastMethodSuccess <> 1) Then
    outFile.WriteLine("Failed to find the certificate.")
    WScript.Quit
End If

outFile.WriteLine("Found: " & cert.SubjectCN)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = CreateObject("Chilkat.Rsa")

' Provide the cert's private key
bUsePrivateKey = 1
success = rsa.SetX509Cert(cert,bUsePrivateKey)

If (success <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Return the RSA signature in base64 encoded form.
rsa.EncodingMode = "base64"

' Sign the utf-8 byte representation of the string.
rsa.Charset = "utf-8"

' You can also choose other hash algorithms, such as SHA-1.
sigBase64 = rsa.SignStringENC("text to sign","SHA-256")
If (rsa.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Base64 signature: " & sigBase64)

outFile.Close