VBScript Requires Chilkat v11.0.0+

RSA Signature/Verify with .key and .cer

See more RSA Examples

Demonstrates how to use a .key file (private key) and digital certificate (.cer, public key) to create and verify an RSA signature. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

set privKey = CreateObject("Chilkat.PrivateKey")

'  Load the private key from an RSA .key file:
success = privKey.LoadPemFile("privateKey.key")
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

set rsa = CreateObject("Chilkat.Rsa")

'  Import the private key into the RSA component:
success = rsa.UsePrivateKey(privKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

'  Create the signature as a hex string:
rsa.EncodingMode = "hex"

strData = "This is the string to be signed."

'  Sign the string using the sha256 hash algorithm.
'  Other valid choices are "md2", "sha1", "sha384",
'  "sha512", and "md5".
hexSig = rsa.SignStringENC(strData,"sha256")

outFile.WriteLine(hexSig)

'  Load a digital certificate from a .cer file:
set cert = CreateObject("Chilkat.Cert")

success = cert.LoadFromFile("myCert.cer")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

set pubKey = CreateObject("Chilkat.PublicKey")
success = cert.GetPublicKey(pubKey)

'  Now verify using a new instance of the RSA object:
set rsa2 = CreateObject("Chilkat.Rsa")

'  Import the public key into the RSA object:
success = rsa2.UsePublicKey(pubKey)
If (success = 0) Then
    outFile.WriteLine(rsa2.LastErrorText)
    WScript.Quit
End If

'  The signature is a hex string, so make sure the EncodingMode is correct:
rsa2.EncodingMode = "hex"

'  Verify the signature:
success = rsa2.VerifyStringENC(strData,"sha256",hexSig)
If (success = 0) Then
    outFile.WriteLine(rsa2.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close