VBScript

RSA SHA256 Signature using Private Key from Java Keystore

See more RSA Examples

Signs plaintext using RSA SHA256 using a key from a Java keystore.

Duplicatest this code:

KeyStore keystore; // key repository for keys containing signature certificate
String alias; // alias for the certificate in the key repository
String password; // password for the certificate's private key
String plaintext; // text being signed


Signature signature = Signature.getInstance("SHA256withRSA");
signature.initSign((PrivateKey) keystore.getKey(alias, password.toCharArray()));
signature.update(plaintext.getBytes("UTF-8"));
byte[] rsa_text= signature.sign();

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set jks = CreateObject("Chilkat.JavaKeyStore")

jksPassword = "secret"

' Load the Java keystore from a file.  The JKS file password is used
' to verify the keyed digest that is found at the very end of the keystore.
' It verifies that the keystore has not been modified.
success = jks.LoadFile(jksPassword,"qa_data/jks/sample_secret.jks")
If (success = 0) Then
    outFile.WriteLine(jks.LastErrorText)
    WScript.Quit
End If

' Get the private key from the JKS.
' The private key password may be different than the file password.
privKeyPassword = "secret"
caseSensitive = 0
set privKey = CreateObject("Chilkat.PrivateKey")
success = jks.PrivateKeyOf(privKeyPassword,"some.alias",caseSensitive,privKey)
If (success = 0) Then
    outFile.WriteLine(jks.LastErrorText)
    WScript.Quit
End If

' Establish the RSA object and tell it to use the private key..
set rsa = CreateObject("Chilkat.Rsa")

success = rsa.UsePrivateKey(privKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Indicate we'll be signing the utf-8 byte representation of the string..
rsa.Charset = "utf-8"

' Sign some plaintext using RSA-SHA256

plaintext = "this is the text to be signed"
binarySignature = rsa.SignString(plaintext,"SHA256")
If (rsa.LastMethodSuccess = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Alternatively, if the signature is desired in some encoded string form,
' such as base64, base64-url, hex, etc.
rsa.EncodingMode = "base64-url"
signatureStr = rsa.SignStringENC(plaintext,"SHA256")
outFile.WriteLine("base64-url RSA signature: " & signatureStr)

outFile.Close