(VBScript) Duplicate openssl dgst -md5 -sign myKey.pem something.txt | openssl enc -base64 -A

Demonstrates how to duplicate the creation of an RSA signature produced by this OpenSSL command:

openssl dgst -md5 -sign myKey.pem something.txt | openssl enc -base64 -A

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set pkey = CreateObject("Chilkat.PrivateKey")

' Load the private key from an RSA PEM file:
success = pkey.LoadPemFile("myKey.pem")

' Get the private key in XML format:
pkeyXml = pkey.GetXml()

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = CreateObject("Chilkat.Rsa")

' Import the private key into the RSA component:
success = rsa.ImportPrivateKey(pkeyXml)
If (success <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' OpenSSL uses BigEndian byte ordering:
rsa.LittleEndian = 0

' The resulting signature will be a Base64 string:
rsa.EncodingMode = "base64"

' For simplicity, we're not loading
' the data to be signed from a file.  We are instead simply
' using a literal string value.  
strData = "This is the text to be signed."

' Hash the input using MD5, and then sign the hash:
' Other valid hash algorithm choices are "md2" and "sha-1".
base64Sig = rsa.SignStringENC(strData,"md5")

outFile.WriteLine(base64Sig)

outFile.WriteLine("Success!")

outFile.Close