(VBScript) Duplicating OpenSSL rsautl (creating RSA signatures)

Demonstrates how to duplicate OpenSSL rsautil RSA signatures.

The Chilkat RSA component's methods for creating RSA signatures (SignBytes, SignBytesENC, SignString, and SignStringENC) are very different from OpenSSL's rsautl command. First, we'll explain what Chilkat's signing methods do, and then what OpenSSL's rsautl does. New signing methods have been added to Chilkat RSA to duplicate OpenSSL rsautl: OpenSslSignBytes, OpenSslSignBytesENC, OpenSslSignString, and OpenSslSignStringENC.

Here's what Chilkat's RSA Sign* methods do:
(Note: Chilkat RSA's Sign* methods generate signatures according to RSA Laboratories' "PKCS #1 v2.0: RSA Cryptography Standard".)

1. Input data is hashed using the hashing algorithm specified.
2. The hash is padded using either PKCS1 v1.5 or PKCS1 PSS padding. PKCS v1.5 involves encoding to ASN.1 before padding.
3. The padded hash is finally RSA signed (i.e. modular exponentiation) and the signature is returned.

OpenSSL rsautl is very different. Here's what it does:

1. The input data is not hashed. It must be a small enough amount of data such that it can be padded and signed. PKCS v1.5 padding is always used. The data is not ASN.1 encoded before padding.
2. The PKCS v1.5 padded data is RSA signed and the signature is returned.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set privKey = CreateObject("Chilkat.PrivateKey")

' Load the private key from an RSA PEM file:
success = privKey.LoadPemFile("private.pem")
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

set rsa = CreateObject("Chilkat.Rsa")
success = rsa.UsePrivateKey(privKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

strData = "secret"
set bd = CreateObject("Chilkat.BinData")
success = bd.AppendString(strData,"utf-8")

success = rsa.SignRawBd(bd)
hexSig = bd.GetEncoded("hex")
outFile.WriteLine(hexSig)

' Recover the data using the corresponding public key:
set pubKey = CreateObject("Chilkat.PublicKey")

' Load the public key from a PEM file:
success = pubKey.LoadFromFile("public.pem")
If (success = 0) Then
    outFile.WriteLine(pubKey.LastErrorText)
    WScript.Quit
End If

set rsa2 = CreateObject("Chilkat.Rsa")
success = rsa2.UsePublicKey(pubKey)
If (success = 0) Then
    outFile.WriteLine(rsa2.LastErrorText)
    WScript.Quit
End If

set bd2 = CreateObject("Chilkat.BinData")
success = bd2.AppendEncoded(hexSig,"hex")

' Recover the original data.
success = rsa2.VerifyRawBd(bd2)
If (success = 0) Then
    outFile.WriteLine(rsa2.LastErrorText)
    WScript.Quit
End If

originalData = bd2.GetString("utf-8")
outFile.WriteLine(originalData)

outFile.Close