(VBScript) RSA Hash Binary Data and Sign (and Verify)

Demonstrates how to sign the hash of binary data. Also demonstrates how to verify the RSA signature.

Note: This example uses methods introduced in Chilkat v9.5.0.77.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load an RSA private key for signing.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set privKey = CreateObject("Chilkat.PrivateKey")
success = privKey.LoadEncryptedPemFile("qa_data/pem/rsa_passwd.pem","passwd")
If (success <> 1) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = CreateObject("Chilkat.Rsa")
success = rsa.ImportPrivateKeyObj(privKey)

' We have some binary data (in hex) to sign
originalData = "0102030405060708090A"
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdData = CreateObject("Chilkat.BinData")
success = bdData.AppendEncoded(originalData,"hex")

' Hash (SHA-256) and sign the hash:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdSignature = CreateObject("Chilkat.BinData")
success = rsa.SignBd(bdData,"sha256",bdSignature)
If (success <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Show the RSA signature in base64
outFile.WriteLine(bdSignature.GetEncoded("base64"))

' ------------------------------------------
' Get the public key from the private key
' pubKey is a Chilkat.PublicKey
Set pubKey = privKey.GetPublicKey()

' Verify the signature..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa2 = CreateObject("Chilkat.Rsa")
success = rsa2.ImportPublicKeyObj(pubKey)

bVerified = rsa2.VerifyBd(bdData,"sha256",bdSignature)
outFile.WriteLine("signature verified: " & bVerified)


outFile.Close