(VBScript) Generate an RSA Key and Get as Base64 DER

Demonstrates how to generate a 2048-bit RSA key and return the public and private parts as unencrypted Base64 encoded DER.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = CreateObject("Chilkat.Rsa")

' Generate a 2048-bit key.  Chilkat RSA supports
success = rsa.GenerateKey(2048)
If (success <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' Get the public part of the key.
' pubKey is a Chilkat.PublicKey
Set pubKey = rsa.ExportPublicKeyObj()

' There are two possible formats for representing the RSA public key 
' in ASN.1 (DER).  The possible formats are PKCS1 and PKCS8.
' We can get either by setting bChoosePkcs1 to 1 or 0.
bChoosePkcs1 = 1
pubKeyBase64Der = pubKey.GetEncoded(bChoosePkcs1,"base64")
outFile.WriteLine("Public Key Base64 DER:")
outFile.WriteLine(pubKeyBase64Der)

' Now get the private key as Base64 DER:
' Get the private part of the key.
' (Note: A public key is actually just a subset of the private key.  
'  If you have the private key, you also have the public key.
'  Thus Chilkat provides a method to get the public key from the private key.)
' privKey is a Chilkat.PrivateKey
Set privKey = rsa.ExportPrivateKeyObj()

' Again, we can get PKCS1 or PKCS8, but with different methods:
privKeyPkcs1 = privKey.GetPkcs1ENC("base64")
outFile.WriteLine("Private Key PKCS1 Base64 DER:")
outFile.WriteLine(privKeyPkcs1)

privKeyPkcs8 = privKey.GetPkcs8ENC("base64")
outFile.WriteLine("Private Key PKCS8 Base64 DER:")
outFile.WriteLine(privKeyPkcs8)


outFile.Close