VBScript

Generate RSA Key and Sign a String

See more RSA Examples

Demonstrates how to generate a new RSA public/private key pair and use it to generate a signature for a string. The (binary) digital signature is returned as a hexidecimalized string. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rsa = CreateObject("Chilkat.Rsa")

' Generate a 2048-bit RSA key.
set privKey = CreateObject("Chilkat.PrivateKey")
success = rsa.GenKey(2048,privKey)

success = rsa.UsePrivateKey(privKey)

' Return the signature in hex.
rsa.EncodingMode = "hex"

strData = "This is the string to be signed."

' Sign the SHA256 hash of the string.
hexSig = rsa.SignStringENC(strData,"sha256")

outFile.WriteLine(hexSig)

' Now verify the signature:
set pubKey = CreateObject("Chilkat.PublicKey")
success = privKey.ToPublicKey(pubKey)
success = rsa.UsePublicKey(pubKey)

success = rsa.VerifyStringENC(strData,"sha256",hexSig)
If (success = 1) Then
    outFile.WriteLine("Signature verified!")
Else
    outFile.WriteLine(rsa.LastErrorText)
End If

' Try it with an invalid signature:
success = rsa.VerifyStringENC(strData,"sha256","not a valid sig")
If (success = 1) Then
    outFile.WriteLine("Signature verified!")
Else
    outFile.WriteLine("Signature validation failed!")
End If

' Try it with invalid data:
success = rsa.VerifyStringENC("Not the original data","sha256",hexSig)
If (success = 1) Then
    outFile.WriteLine("Signature verified!")
Else
    outFile.WriteLine("Signature validation failed!")
End If


outFile.Close