VBScript

REST URL Encode Path Parts and Query Params

See more REST Examples

When passing a path to a Chilkat REST function, the path parts and query params should be URL encoded. This example explains.. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example demonstrates how to URL encode the path passed to a REST function.
' It is demonstrated with an Amazon SP API GET request to get details about a listings item for a selling partner.
' See https://developer-docs.amazon.com/sp-api/docs/listings-items-api-v2021-08-01-reference#getlistingsitem

set rest = CreateObject("Chilkat.Rest")

' Connect to the REST server.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("sellingpartnerapi-eu.amazon.com",port,bTls,bAutoReconnect)

success = rest.ClearAllQueryParams()
success = rest.AddQueryParam("marketplaceids","XYZABC123")
success = rest.AddQueryParam("includedData","offers")

success = rest.AddHeader("x-amz-access-token","YOUR_ACCESS_TOKEN")

set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "YOUR_AWS_APP_ID"
authAws.SecretKey = "YOUR_AWS_APP_SECRET_KEY"
authAws.Region = "eu-west-1"
authAws.ServiceName = "execute-api"
success = rest.SetAuthAws(authAws)

' The path that is passed to FullRequestNobBody

' Here's a sample path that is not yet URL encoded.
path = "/listings/2022-07-01/items/ABCDEFGHIJ/100x100_28g_LANCETS(BOXED)"

' The path passed to FullRequestNoBody needs to have the parts URL-encoded.
' The "/" chars are not URL encoded, but the individual path parts should be URL encoded.
' For example:  /listings/2022-07-01/items/ABCDEFGHIJ/100x100_28g_LANCETS%28BOXED%29

' In this case, we'll prepare the path like this:
set sbPath = CreateObject("Chilkat.StringBuilder")
success = sbPath.Append("100x100_28g_LANCETS(BOXED)")
' URL encode the contents of the sbPath.
success = sbPath.Encode("url","utf-8")
' Prepend the remaining which does not need to be URL encoded.
success = sbPath.Prepend("/listings/2022-07-01/items/ABCDEFGHIJ/")

outFile.WriteLine("URL encoded path: " & sbPath.GetAsString())

responseJson = rest.FullRequestNoBody("GET",sbPath.GetAsString())
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(responseJson)
outFile.WriteLine("----")

outFile.Close