(VBScript) REST Read Response with Stream API

Demonstrates how to make a REST call that returns a binary body, and to receive the body through a stream API.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("s3.amazonaws.com",port,bTls,bAutoReconnect)

' ----------------------------------------------------------------------------
' Important: For buckets created in regions outside us-east-1,
' there are three important changes that need to be made.
' See Working with S3 Buckets in Non-us-east-1 Regions for the details.
' ----------------------------------------------------------------------------

' Provide AWS credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
success = rest.SetAuthAws(authAws)

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkat100".
rest.Host = "chilkat100.s3.amazonaws.com"

' Send the request to download the JPG.
success = rest.SendReqNoBody("GET","/starfish.jpg")
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Read the response header.
responseStatusCode = rest.ReadResponseHeader()
If (responseStatusCode < 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response status code = " & responseStatusCode)

' We expect a 200 response status if the JPG data is coming.
' Otherwise, we'll get a string response body with an error message(or no response body).
If (responseStatusCode <> 200) Then
    errResponse = rest.ReadRespBodyString()
    If (rest.LastMethodSuccess <> 1) Then
        outFile.WriteLine(rest.LastErrorText)
    Else
        outFile.WriteLine(errResponse)
    End If

    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Stream")
set bodyStream = CreateObject("Chilkat.Stream")
' Set a 10 second read timeout for the stream. 
' (Give up if no data arrives within 10 seconds after calling a read method.)
bodyStream.ReadTimeoutMs = 10000

' Create a background thread task to read the response body (which feeds
' it to the bodyStream object.)
' readResponseBodyTask is a Chilkat.Task
Set readResponseBodyTask = rest.ReadRespBodyStreamAsync(bodyStream,1)

' Start the task. 
success = readResponseBodyTask.Run()

' The application can now read the bodyStream...
Do While (bodyStream.EndOfStream <> 1)

    ' Read the next chunk of bytes (whatever is immediately available,
    ' or wait for more data (up to 10 seconds because we set the stream's ReadTimeoutMs property)
    nextChunk = bodyStream.ReadBytes()
    If (bodyStream.LastMethodSuccess <> 1) Then
        outFile.WriteLine("Failed to receive more response data.")
        ' Make sure the background task is aborted/cancelled.
        success = readResponseBodyTask.Cancel()

        WScript.Quit
    End If

    ' OK.. the app has the next chunk of the body, and may do whatever it wishes with it...
Loop

outFile.WriteLine("Successfully received the entire response body.")

outFile.Close