VBScript

Send JSON REST Request, Get JSON Response

See more REST Examples

Demonstrates sending a RESTful JSON request, and receiving a JSON response. This example will create a bucket in Google Cloud Storage (which involves sending and receiving JSON). VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example will create a bucket in Google Cloud Storage.

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set gAuth = CreateObject("Chilkat.AuthGoogle")
' Obtain an access token as shown in one of the following examples:
' See Get Access Token using a Service Account JSON Key
' See Get Access Token using a P12 File

set rest = CreateObject("Chilkat.Rest")

' Connect using TLS.
bAutoReconnect = 1
success = rest.Connect("www.googleapis.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access key)
success = rest.SetAuthGoogle(gAuth)

' Build the JSON request body for creating a bucket.
' The only required property is the "name", but we'll add more
' to make a better example..
set jsonReqBody = CreateObject("Chilkat.JsonObject")
success = jsonReqBody.AppendString("name","chilkat-bucket-c")
success = jsonReqBody.AppendString("kind","storage#bucket")
success = jsonReqBody.AppendString("location","US")

set objVersioning = CreateObject("Chilkat.JsonObject")
success = jsonReqBody.AppendObject2("versioning",objVersioning)
success = objVersioning.AppendBool("enabled",1)

' Show the HTTP request body we'll be sending.
outFile.WriteLine(jsonReqBody.Emit())

' Add the required query parameter.
' See https://cloud.google.com/storage/docs/json_api/v1/buckets/insert
success = rest.AddQueryParam("project","chilkattest-1050")

' Add the Content-Type HTTP request header.
success = rest.AddHeader("Content-Type","application/json; charset=UTF-8")

jsonResponseStr = rest.FullRequestString("POST","/storage/v1/b",jsonReqBody.Emit())
If (rest.LastMethodSuccess = 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Show the JSON response.  (See below for a sample JSON response.)
outFile.WriteLine("Json Response: " & jsonResponseStr)

' {
'  "kind": "storage#bucket",
'  "id": "chilkat-bucket-c",
'  "selfLink": "https://www.googleapis.com/storage/v1/b/chilkat-bucket-c",
'  "projectNumber": "999992999999",
'  "name": "chilkat-bucket-c",
'  "timeCreated": "2016-04-29T21:08:10.451Z",
'  "updated": "2016-04-29T21:08:10.451Z",
'  "metageneration": "1",
'  "owner": {
'   "entity": "project-owners-999992999999"
'  },
'  "location": "US",
'  "versioning": {
'   "enabled": true
'  },
'  "storageClass": "STANDARD",
'  "etag": "CAE="
' }
' 

outFile.Close