VBScript

Send XML REST Request, Get Response with No Body (Google Cloud Storage)

See more REST Examples

Demonstrates sending a RESTful XML request, and receiving a response where the expected response is a header with no body (Content-Length = 0). This example will create a bucket in Google Cloud Storage using the Google Cloud Storage XML API.

See Create a Bucket using the XML API for additional request options.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example will create a bucket in Google Cloud Storage using the XML API.

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set gAuth = CreateObject("Chilkat.AuthGoogle")
' Obtain an access token as shown in one of the following examples:
' See Get Access Token using a Service Account JSON Key
' See Get Access Token using a P12 File

set rest = CreateObject("Chilkat.Rest")

' Connect using TLS.
bAutoReconnect = 1
success = rest.Connect("www.googleapis.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access key)
success = rest.SetAuthGoogle(gAuth)

' Build the XML request body for creating a bucket.
' See https://cloud.google.com/storage/docs/xml-api/put-bucket-create
set xmlReqBody = CreateObject("Chilkat.Xml")
xmlReqBody.Tag = "CreateBucketConfiguration"
xmlReqBody.NewChild2 "LocationConstraint","us"
xmlReqBody.NewChild2 "StorageClass","STANDARD"

' Show the HTTP request body we'll be sending.
outFile.WriteLine(xmlReqBody.GetXml())

' There are no query parameters...

' The HOST header must be specified, because it needs to be different than
' the domain previously passed to the Connect method.
' The name of the bucket is the 1st part of the HOST header.
success = rest.AddHeader("Host","chilkat-example-bucket.storage.googleapis.com")

' The project ID is specified in an HTTP request header
success = rest.AddHeader("x-goog-project-id","chilkattest-1050")

' In this case, the response body is expected to be empty.  We can still
' call FullRequestString.  We expect an empty string to be returned.
responseStr = rest.FullRequestString("PUT","/",xmlReqBody.GetXml())
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Check the response status code to make sure it is 200.
responseStatus = rest.ResponseStatusCode
outFile.WriteLine("Response Status Code = " & responseStatus)

outFile.Close