VBScript

REST Download Binary File to Memory

See more REST Examples

Download a binary file to a Chilkat BinData object. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' We're going to download a sample MS-Word doc file.
' The URLs of our MS-Word sample documents are:

' https://www.chilkatdownload.com/sample_data/sample.doc
' https://www.chilkatdownload.com/sample_data/sample.docx

pathPartOfUrl = "/sample_data/sample.doc"
domain = "chilkatdownload.com"

bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect(domain,port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

set bd = CreateObject("Chilkat.BinData")
success = rest.FullRequestNoBodyBd("GET",pathPartOfUrl,bd)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A 200 response is expected for actual success.
' If we don't get a 200 response, then the response body was not actually
' the file data, but it was text containing error information.
If (rest.ResponseStatusCode <> 200) Then
    set sbErrorText = CreateObject("Chilkat.StringBuilder")
    success = sbErrorText.AppendBd(bd,"utf-8",0,0)
    outFile.WriteLine(sbErrorText.GetAsString())
    outFile.WriteLine("-- Failed.")
    WScript.Quit
End If

' Save to a local file.
' Change the file path based on your operating system or needs...
success = bd.WriteFile("c:/temp/qa_output/sample.doc")
If (success <> 1) Then
    outFile.WriteLine("Failed to save to local file.")
    WScript.Quit
End If

outFile.WriteLine("REST Download of MS-Word File was successful.")

outFile.Close