VBScript

Client Certificate in REST (USB Token or Smartcard)

See more REST Examples

Demonstrates how to use a client certificate with a REST connection where the certificate and private key are located on a USB token or smart card. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example shows how to use the Chilkat socket object's connection.
set rest = CreateObject("Chilkat.Rest")
set socket = CreateObject("Chilkat.Socket")

' Set the certificate to be used for mutual TLS authentication
set cert = CreateObject("Chilkat.Cert")

' If the smartcard or token requires a PIN...
cert.SmartCardPin = "000000"

success = cert.LoadFromSmartcard("")
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

success = socket.SetSslClientCert(cert)
If (success <> 1) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

' Establish the connection using the socket object (with client certificate authentication).
bTls = 1
port = 443
maxWaitMs = 5000
success = socket.Connect("www.example.com",port,bTls,maxWaitMs)
If (success <> 1) Then
    outFile.WriteLine("Connect Failure Error Code: " & socket.ConnectFailReason)
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

bAutoReconnect = 1

' Use the connection:
success = rest.UseConnection(socket,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' At this point we are connected and can make REST calls...
' For example..
responseJson = rest.FullRequestNoBody("GET","/someQuery")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If


outFile.Close