VBScript

REST Asynchronous Streaming Upload File

See more REST Examples

Demonstrates how to asynchronous streaming upload a file to cloud storage. This particular example demonstrates an upload to the Azure Cloud Storage service. The same concepts apply to S3, Google Cloud, and Google Drive. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' Connect to the Azure Storage Blob Service
bTls = 1
port = 443
bAutoReconnect = 1
' In this example, the storage account name is "chilkat".
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide Azure Cloud credentials for the REST call.
set azAuth = CreateObject("Chilkat.AuthAzureStorage")
azAuth.AccessKey = "AZURE_ACCESS_KEY"
' The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
' This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

' Set some request headers.
success = rest.AddHeader("x-ms-blob-content-disposition","attachment; filename=""thisIsATest.txt""")
success = rest.AddHeader("x-ms-blob-type","BlockBlob")
success = rest.AddHeader("x-ms-meta-m1","v1")
success = rest.AddHeader("x-ms-meta-m2","v2")

' Note: The application does not need to explicitly set the following
' headers: x-ms-date, Authorization, and Content-Length.  These headers
' are automatically set by Chilkat.

set sendStream = CreateObject("Chilkat.Stream")

' Define the source data for the stream to be a file.
sendStream.SourceFile = "qa_data/hamlet.xml"

' Create a background thread task to upload from the stream
' The name of the Azure storage container is "test".
' task is a Chilkat.Task
Set task = rest.FullRequestStreamAsync("PUT","/test/thisIsATest.txt",sendStream)

' Start the task. 
success = task.Run()

' In this example, we'll simply sleep and periodically
' check to see if the REST upload if finished.
curPctDone = 0
Do While task.Finished <> 1
    task.SleepMs 100
Loop

' Check to see if the call to FullRequestStream in the background thread pool succeeded.
If (task.TaskSuccess <> 1) Then
    ' Show what would've been the LastErrorText had FullRequestStream been called synchronously
    outFile.WriteLine(task.ResultErrorText)

    WScript.Quit
End If

responseStatusCode = rest.ResponseStatusCode

' When successful, the Azure Storage service will respond with a 201 response code,
' with an empty body.  Therefore, in the success condition, the responseStr is empty.
If (responseStatusCode = 201) Then
    outFile.WriteLine("File uploaded.")
Else
    ' It failed, so examine the response body, if one was returned:
    ' Given that FullRequestStream returns a string, the return value is obtained via GetResultString.
    responseBodyStr = task.GetResultString()
    outFile.WriteLine("response body (if any): " & responseBodyStr)

    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
End If


outFile.Close