VBScript

Rabobank OAuth2 Access Token

See more OAuth2 Examples

Demonstrates how to get an OAuth 2.0 access token to access Rabobank API's

Important: This example is for desktop apps only. (It is not for web-based applications.)

Your app defined in the Rabobank portal should look something like this. (Our test app is named "chilkat". You should name your app something else.)

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' For more information about the OAuth2, see OAuth 2.0 Authorization Flow

set oauth2 = CreateObject("Chilkat.OAuth2")

' This should be the port in the localhost callback URL for your app.  
' The callback URL would look like "http://localhost:3017/" if the port number is 3017.
oauth2.ListenPort = 3017

' IMPORTANT: Don't forget to subscribe your Rabobank application to the OAuth 2.0 services in the Rabobank Online Developer Portal.
' IMPORTANT: Don't forget to subscribe your Rabobank application to the OAuth 2.0 services in the Rabobank Online Developer Portal.
' IMPORTANT: Don't forget to subscribe your Rabobank application to the OAuth 2.0 services in the Rabobank Online Developer Portal.
' IMPORTANT: Don't forget to subscribe your Rabobank application to the OAuth 2.0 services in the Rabobank Online Developer Portal.

' See also https://developer.rabobank.nl/faq

oauth2.AuthorizationEndpoint = "https://api-sandbox.rabobank.nl/openapi/sandbox/oauth2/authorize"
oauth2.TokenEndpoint = "https://api-sandbox.rabobank.nl/openapi/sandbox/oauth2/token"

' Replace these with actual values.
oauth2.ClientId = "YOUR_APP_CLIENT_ID"
' This is your app password:
oauth2.ClientSecret = "YOUR_APP_CLIENT_SECRET"

oauth2.CodeChallenge = 0
' Provide a SPACE separated list of scopes, as defined in the Rabobank API documentation, 
' such as at https://developer-sandbox.rabobank.nl/reference/accounts-ais-sb/3-0-8

' Important: To get a refresh token in the final response, you have to ask for "offline_access" scope
oauth2.Scope = "ais.balances.read ais.transactions.read-90days ais.transactions.read-history"

' Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> 1) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("url = " & url)

' Launch the default browser on the system and navigate to the url.
' The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = 0) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' Wait for the user to approve or deny authorization in the browser.
numMsWaited = 0
Do While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If the browser does not respond within the specified time, AuthFlowState will be:
' 
' 1: Waiting for Redirect - The OAuth2 background thread is waiting for the browser's redirect request.
' 2: Waiting for Final Response - The thread is awaiting the final access token response.
' In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    outFile.WriteLine("No response from the browser!")
    WScript.Quit
End If

' Check AuthFlowState to determine if authorization was granted, denied, or failed:
' 
' 3: Success - OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
' 4: Access Denied - OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
' 5: Failure - OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    outFile.WriteLine("OAuth2 failed to complete.")
    outFile.WriteLine(oauth2.FailureInfo)
    WScript.Quit
End If

If (oauth2.AuthFlowState = 4) Then
    outFile.WriteLine("OAuth2 authorization was denied.")
    outFile.WriteLine(oauth2.AccessTokenResponse)
    WScript.Quit
End If

If (oauth2.AuthFlowState <> 3) Then
    outFile.WriteLine("Unexpected AuthFlowState:" & oauth2.AuthFlowState)
    WScript.Quit
End If

outFile.WriteLine("OAuth2 authorization granted!")
outFile.WriteLine("Access Token = " & oauth2.AccessToken)

' Get the full JSON response:
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(oauth2.AccessTokenResponse)
json.EmitCompact = 0

' The JSON response looks like this:

' {
'   "token_type": "Bearer",
'   "access_token": "AAIkYTU0ZWM ... sxE0KL0HHWw",
'   "expires_in": 3600,
'   "consented_on": 1584641121,
'   "scope": "ais.balances.read ais.transactions.read-90days ais.transactions.read-history",
'   "refresh_token": "AAJXXSdN ... Uiblz9ILkxNBlytRGA",
'   "refresh_token_expires_in": 157784760,
'   "expires_on": "1584644722"
' }

outFile.WriteLine(json.Emit())

' Save the JSON to a file to be used in future requests.
set fac = CreateObject("Chilkat.FileAccess")
success = fac.WriteEntireTextFile("qa_data/tokens/rabobank.json",json.Emit(),"utf-8",0)

outFile.Close