(VBScript) Quickbooks Revoke OAuth2 Token

Demonstrates how to revoke a QuickBooks OAuth2 access token.

For more information, see https://developer.intuit.com/app/developer/qbo/docs/develop/authentication-and-authorization/oauth-2.0#revoke-token-disconnect

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example assumes we previously obtained an OAuth2 access token for QuickBooks.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/qb-access-token.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load qb-access-token.json")
    WScript.Quit
End If

' The access token JSON looks something like this:

' {
'   "expires_in": 3600,
'   "x_refresh_token_expires_in": 8726400,
'   "refresh_token": "L011546037639r ... 3vR2DrbOmg0Sdagw",
'   "access_token": "eyJlbmMiOiJBMTI4Q0 ... oETJEMbeggg",
'   "token_type": "bearer"
' }

' This code sends the following request:

' POST https://developer.api.intuit.com/v2/oauth2/tokens/revoke HTTP/1.1
' Accept: application/json
' Authorization: Basic UTM0dVB...wM1d2
' Content-Type: application/json
' 
' {
'     "token": "{bearerToken or refreshToken}"
' }

' Use this online tool to generate HTTP code from a sample request: 
' Generate Code from a Sample HTTP Request

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")
http.SetRequestHeader "Accept","application/json"
http.BasicAuth = 1
http.Login = "QUICKBOOKS-CLIENT-ID"
http.Password = "QUICKBOOKS-CLIENT-SECRET"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("token",jsonToken.StringOf("access_token"))

url = "https://developer.api.intuit.com/v2/oauth2/tokens/revoke"
' resp is a Chilkat.HttpResponse
Set resp = http.PostJson3(url,"application/json",json)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response status code = " & resp.StatusCode)
outFile.WriteLine("Response body:")
outFile.WriteLine(resp.BodyStr)


outFile.Close