VBScript

Refresh QuickBooks OAuth2 Access Token

See more QuickBooks Examples

Demonstrates how to refresh a QuickBooks OAuth2 access token. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' See Get QuickBooks OAuth2 Access Token 
' for sample code showing how to obtain a QuickBooks access token for desktop apps.

' This example assumes we previously obtained an OAuth2 access token for QuickBooks.

set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/qb-access-token.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load qb-access-token.json")
    WScript.Quit
End If

' The access token JSON looks something like this:

' {
'   "expires_in": 3600,
'   "x_refresh_token_expires_in": 8726400,
'   "refresh_token": "L011546037639r ... 3vR2DrbOmg0Sdagw",
'   "access_token": "eyJlbmMiOiJBMTI4Q0 ... oETJEMbeggg",
'   "token_type": "bearer"
' }

set oauth2 = CreateObject("Chilkat.OAuth2")

oauth2.TokenEndpoint = "https://oauth.platform.intuit.com/oauth2/v1/tokens/bearer"

' Replace these with actual values.
oauth2.ClientId = "QUICKBOOKS-CLIENT-ID"
oauth2.ClientSecret = "QUICKBOOKS-CLIENT-SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

' Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success = 0) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' The response contains a new access token, but we must keep
' our existing refresh token for when we need to refresh again in the future.
success = jsonToken.UpdateString("access_token",oauth2.AccessToken)

' Save the new JSON access token response to a file.
' The access + refresh tokens contained in this JSON will be needed for the next refresh.
set sbJson = CreateObject("Chilkat.StringBuilder")
jsonToken.EmitCompact = 0

success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/qb-access-token.json","utf-8",0)

outFile.WriteLine("OAuth2 token refreshed!")
outFile.WriteLine("New Access Token = " & oauth2.AccessToken)

outFile.Close