(VBScript) QR Code Generator via api.qrserver.com REST API

See more HTTP Examples

Demonstrates how to generate a QR code using the api.qrserver.com REST API service.

For more information, see https://goqr.me/api/doc/create-qr-code/

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' Send the following GET request to get a binary response.
' The body of the binary response contains the image data for the QR code.
' https://api.qrserver.com/v1/create-qr-code/?data=[URL-encoded-text]&size=[pixels]x[pixels]

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set queryParams = CreateObject("Chilkat.JsonObject")
success = queryParams.UpdateString("data","Hello World")
success = queryParams.UpdateString("size","100x100")

' Get a PNG file..
' Possible formats are:
' png
' gif
' jpeg
' jpg
' svg
' eps
' Case matters.  Use lowercase.
success = queryParams.UpdateString("format","png")

' Send the GET request to an endpoint.
' Chilkat will add the url-encoded query params passed in the JSON.
' resp is a Chilkat.HttpResponse
Set resp = http.QuickRequestParams("GET","https://api.qrserver.com/v1/create-qr-code/",queryParams)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Did it succeed?
If (resp.StatusCode <> 200) Then
    ' The response body, if anything, would not be the image data, but would likely be the error text (or HTML, or whatever...)
    outFile.WriteLine(resp.BodyStr)
    outFile.WriteLine("Response status = " & resp.StatusCode)
    outFile.WriteLine("Failed.")

    WScript.Quit
End If

' Success if we get here..
' Save the binary body as the PNG file, or you can get the bytes of the PNG..
success = resp.SaveBodyBinary("c:/temp/qa_output/qr_code.png")

' Or get the bytes:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")
success = resp.GetBodyBd(bd)
' Use the bytes in bd...
' See the online reference documentation for the function to access the bytes directly.

outFile.WriteLine("Success.")

outFile.Close