VBScript

SOCKS4, SOCKS5 Proxy for POP3

Demonstrates how to communicate with a POP3 server through a SOCKS4 or SOCKS5 proxy. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for receiving (POP3) 
' and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan")

' To use a SOCKS4 or SOCKS5 proxy, simply set the following
' properties prior to making any calls that communicate with
' a POP3 server:
' The SOCKS hostname may be a domain name or 
' IP address:
mailman.SocksHostname = "www.mysocksproxyserver.com"
mailman.SocksPort = 1080
mailman.SocksUsername = "myProxyLogin"
mailman.SocksPassword = "myProxyPassword"
' Set the SOCKS version to 4 or 5 based on the version
' of the SOCKS proxy server:
mailman.SocksVersion = 5
' Note: SOCKS4 servers only support usernames without passwords.
' SOCKS5 servers support full login/password authentication.

' Set the POP3 server's hostname
mailman.MailHost = "pop.example.com"

' Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

' Copy the all email from the user's POP3 mailbox 
' into a bundle object.  The email remains on the server.
set bundle = CreateObject("Chilkat.EmailBundle")
keepOnServer = 1
headersOnly = 0
' Irrelevent because we are NOT downloading headers-only
numBodyLines = 0
success = mailman.FetchAll(keepOnServer,headersOnly,numBodyLines,bundle)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

set email = CreateObject("Chilkat.Email")
i = 0
Do While i < bundle.MessageCount
    success = bundle.EmailAt(i,email)

    outFile.WriteLine("From: " & email.From)
    outFile.WriteLine("Subject: " & email.Subject)
    i = i + 1
Loop

success = mailman.Pop3EndSession()

outFile.Close