VBScript

Read POP3 Mail Headers

Reads the header for each email in a POP3 mailbox and display the FROM and SUBJECT header fields. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for receiving (POP3) 
' and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan")

' Set the POP3 server's hostname
mailman.MailHost = "pop.example.com"

' Set the POP3 login/password.
mailman.PopUsername = "****"
mailman.PopPassword = "****"

' Read mail headers and one line of the body.
set bundle = CreateObject("Chilkat.EmailBundle")
keepOnServer = 1
headersOnly = 1
numBodyLines = 1
success = mailman.FetchAll(keepOnServer,headersOnly,numBodyLines,bundle)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

set email = CreateObject("Chilkat.Email")
i = 0
Do While i < bundle.MessageCount
    success = bundle.EmailAt(i,email)

    ' Display the From email address and the subject.
    outFile.WriteLine("From: " & email.From)
    outFile.WriteLine("Subject: " & email.Subject)

    i = i + 1
Loop

outFile.Close