(VBScript) POP3 over Multiple Hop SSH

Demonstrates how to read POP3 email (using TCP or TLS) tunneled through mulitple-hop SSH. The scheme looks like this:

Application => ServerSSH1 => ServerSSH2 => POP3Server

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ssh")
set ssh1 = CreateObject("Chilkat.Ssh")

' Connect directly to the 1st SSH server.
success = ssh1.Connect("serverssh1.com",22)
If (success <> 1) Then
    outFile.WriteLine(ssh1.LastErrorText)
    WScript.Quit
End If

' Authenticate using login/password:
success = ssh1.AuthenticatePw("ssh1Login","ssh1Password")
If (success <> 1) Then
    outFile.WriteLine(ssh1.LastErrorText)
    WScript.Quit
End If

' Connect through the 1st SSH connection to reach a 2nd SSH server.
' Note: Any number of SSH connections may be simultaneously tunneled through a single
' existing SSH connection.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ssh")
set ssh2 = CreateObject("Chilkat.Ssh")
success = ssh2.ConnectThroughSsh(ssh1,"serverssh2.com",22)
If (success <> 1) Then
    outFile.WriteLine(ssh2.LastErrorText)
    WScript.Quit
End If

' Authenticate with ssh2...
success = ssh2.AuthenticatePw("ssh2Login","ssh2Password")
If (success <> 1) Then
    outFile.WriteLine(ssh2.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

' Tell the mailman object to connect to the POP3 server though the ssh2 tunnel (which itself is routed through ssh1).
' The connection looks like this:  Application => ServerSSH1 => ServerSSH2 => POP3Server
success = mailman.UseSsh(ssh2)
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

' Set the POP3 server's hostname
mailman.MailHost = "pop.someMailServer.com"

' Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

' Establish the POP3 connection through the ssh2 tunnel.
success = mailman.Pop3BeginSession()
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

' Get the number of messages in the mailbox.
numMessages = mailman.GetMailboxCount()

i = 1

Do While i <= numMessages

    ' email is a Chilkat.Email
    Set email = mailman.FetchByMsgnum(i)
    If (mailman.LastMethodSuccess <> 1) Then
        outFile.WriteLine(mailman.LastErrorText)
        WScript.Quit
    End If

    outFile.WriteLine(email.From & ": " & email.Subject & vbLf)

    i = i + 1
Loop

' Close the connection with the POP3 server.  (This closes the tunnel through ssh2)
' The connection with ssh2 is still alive, and may be used for more connections.
success = mailman.Pop3EndSession()

' Close the connection with ssh2.  (This closes the the tunnel through ssh1.)
' The connection with ssh1 is still alive, and may be used for more connections.

ssh2.Disconnect 

ssh1.Disconnect 

outFile.Close