(VBScript) POP3 to SMTP Forwarder

Read a POP3 mailbox and forwards the email to another email address, keeping the recipients in the original email the same.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

' Set the POP3 server's hostname
mailman.MailHost = "pop.example.com"

' Set the POP3 login/password.
mailman.PopUsername = "MY_LOGIN"
mailman.PopPassword = "MY_PASSWORD"

' The the UIDLs for all email in the POP3 mailbox.
' saUidls is a Chilkat.StringArray
Set saUidls = mailman.GetUidls()
If (mailman.LastMethodSuccess = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

' Download the email from the server.  Call FetchMultipleMime
' because we don't want to load the emails into email objects.
' (We'll delete the emails that are forwarded without error.)
' Note: It is not reasonable to call this method for a mailbox containing
' a huge number of emails.  For large mailboxes, it's better to download
' one by one and process each email independently. This way, if a 
' server or communications error occurs, it's possible to write code
' that can resume.
' saMime is a Chilkat.StringArray
Set saMime = mailman.FetchMultipleMime(saUidls)

If (mailman.LastMethodSuccess = 0) Then

    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

' Set the SMTP hostname for sending.
mailman.SmtpHost = "smtp.example.com"
mailman.SmtpUsername = "MY_SMTP_LOGIN"
mailman.SmtpPassword = "MY_SMTP_PASSWORD"

n = saMime.Count

fromAddr = "me@example.com"
toAddr = "recipient@somewhere.com"

bAllOk = 1

i = 0
Do While i < n

    strMime = saMime.GetString(i)

    ' Forward the email.
    success = mailman.SendMime(fromAddr,toAddr,strMime)
    If (success <> 1) Then
        bAllOk = 0
        outFile.WriteLine(mailman.LastErrorText)
        ' Force loop exit.
        i = n
    End If

    i = i + 1
Loop

' Remove the emails in saUidls from the POP3 server.
If (bAllOk = 1) Then
    success = mailman.DeleteMultiple(saUidls)
    If (success <> 1) Then
        outFile.WriteLine(mailman.LastErrorText)
    End If

End If

outFile.WriteLine("bAllOk = " & bAllOk)

outFile.Close