(VBScript) POP3 Fetch Mime Source of Email by UIDL

Demonstrates how to fetch the MIME source of a single email by UIDL.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

mailman.MailHost = "pop.example.com"

mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

mailman.MailPort = 995
mailman.PopSsl = 1

' sa is a Chilkat.StringArray
Set sa = mailman.GetUidls()
If (mailman.LastMethodSuccess = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

numUidls = sa.Count
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdMime = CreateObject("Chilkat.BinData")

' Download the 1st email and save to a file.
If (numUidls > 0) Then
    uidl = sa.GetString(0)
    outFile.WriteLine(uidl)

    ' Download the MIME source of the email into bdMime.
    ' The bdMime contains the email exactly as it is on the mail server.
    success = mailman.FetchMimeBd(uidl,bdMime)
    If (success = 0) Then
        outFile.WriteLine(mailman.LastErrorText)
        WScript.Quit
    End If

    success = bdMime.WriteFile("qa_output/firstEmail.eml")
End If


outFile.Close