VBScript

Download POP3 Email to MIME

Download the email from a POP3 mailbox directly into MIME, without parsing into email objects. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for receiving (POP3) 
' and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan")

' Set the POP3 server's hostname
mailman.MailHost = "pop.example.com"

' Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

' First, get the complete set of UIDLs for the email in the POP3 mailbox:
set stUidls = CreateObject("Chilkat.StringTable")
success = mailman.FetchUidls(stUidls)
If (success = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

' Download each email as MIME.
' If desired, the MIME can be loaded into an email object.
set bdMime = CreateObject("Chilkat.BinData")
set email = CreateObject("Chilkat.Email")

count = stUidls.Count
i = 0
Do While i < count
    success = mailman.FetchMimeBd(stUidls.StringAt(i),bdMime)
    If (success = 0) Then
        outFile.WriteLine(mailman.LastErrorText)
        WScript.Quit
    End If

    success = email.SetFromMimeBd(bdMime)
    outFile.WriteLine("From: " & email.From)
    outFile.WriteLine("Subject: " & email.Subject)

    i = i + 1
Loop

outFile.Close