VBScript Requires Chilkat v11.0.0+

PKCS11 Import an Existing RSA Public Key onto the HSM

See more PKCS11 Examples

Demonstrates how to import an existing RSA Public Key onto a smart card or token.

Note: This example requires Chilkat v9.5.0.96 or later.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  Note: Chilkat's PKCS11 implementation runs on Windows, Linux, Mac OS X, and other supported operating systems.

set pkcs11 = CreateObject("Chilkat.Pkcs11")

'  Use the PKCS11 driver (.dll, .so, .dylib) for your particular HSM.
'  (The format of the path will change with the operating system.  Obviously, "C:/" is not used on non-Windows systems.
pkcs11.SharedLibPath = "C:/Program Files (x86)/Gemalto/IDGo 800 PKCS#11/IDPrimePKCS1164.dll"

'  Establish a logged-on session.
pin = "0000"
userType = 1
success = pkcs11.QuickSession(userType,pin)
If (success = 0) Then
    outFile.WriteLine(pkcs11.LastErrorText)
    WScript.Quit
End If

'  Generate a new 2048-bit RSA key.
set rsa = CreateObject("Chilkat.Rsa")
set privKey = CreateObject("Chilkat.PrivateKey")
success = rsa.GenKey(2048,privKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

'  Get the public key information as XML, so we can access the modulus and exponent.
set xml = CreateObject("Chilkat.Xml")
set pubKey = CreateObject("Chilkat.PublicKey")
success = privKey.ToPublicKey(pubKey)
success = xml.LoadXml(pubKey.GetXml())

set attrs = CreateObject("Chilkat.JsonObject")
'  Specify the type of object, and the type of key.
success = attrs.UpdateString("class","CKO_PUBLIC_KEY")
success = attrs.UpdateString("key_type","CKK_RSA")
'  Add an optional label if desired.
success = attrs.UpdateString("label","RSA Public Key 1")
'  Allow the key to be use for verify, wrapping, and encryption operations.
success = attrs.UpdateBool("verify",1)
success = attrs.UpdateBool("wrap",1)
success = attrs.UpdateBool("encrypt",1)

'  Make this a session-only public key.
'  To store the public key on the token so that it persists after the PKCS11 session, set token = 1.
success = attrs.UpdateBool("token",0)

'  Provide the RSA public key material
success = attrs.UpdateString("modulus",xml.GetChildContent("Modulus"))
success = attrs.UpdateString("public_exponent",xml.GetChildContent("Exponent"))

'  Create the RSA public key.
'  Returns the PKCS11 object handle of the created key.
objHandle = pkcs11.CreatePkcs11Object(attrs)
If (objHandle = 0) Then
    outFile.WriteLine(pkcs11.LastErrorText)
    outFile.WriteLine("Failed.")
Else
    outFile.WriteLine("PKCS11 object handle = " & objHandle)
    outFile.WriteLine("Successfully imported an RSA key..")
End If

success = pkcs11.Logout()
success = pkcs11.CloseSession()

outFile.Close