VBScript Requires Chilkat v11.0.0+

RSASSA-PSS Sign String to Create Base64 PCKS7 Signature

See more Digital Signatures Examples

Signs a string to create a PKCS7 signature in the base64 encoding. The signature algorithm is RSASSA-PSS with SHA256. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

set crypt = CreateObject("Chilkat.Crypt2")

'  Get a digital certificate with private key from a .pfx
'  (Chilkat has many different ways to provide a cert + private key for siging.
'  Using a PFX is just one possible option.)
set pfx = CreateObject("Chilkat.Pfx")
success = pfx.LoadPfxFile("qa_data/rsassa-pss/privatekey.pfx","PFX_PASSWORD")
If (success = 0) Then
    outFile.WriteLine(pfx.LastErrorText)
    WScript.Quit
End If

'  Get the certificate to be used for signing.
'  (The typical case for a PFX is that it contains a cert with an associated private key,
'  as well as other certificates in the chain of authentication.  The cert with the private
'  key should be in the first position at index 0.)

set cert = CreateObject("Chilkat.Cert")
success = pfx.CertAt(0,cert)
If (success = 0) Then
    outFile.WriteLine(pfx.LastErrorText)
    WScript.Quit
End If

success = crypt.SetSigningCert(cert)

'  Indicate that RSASSA-PSS with SHA256 should be used.
crypt.SigningAlg = "pss"
crypt.HashAlgorithm = "sha256"

crypt.EncodingMode = "base64"

'  Sign a string and return the base64 PKCS7 detached signature
originalText = "This is a test"
pkcs7sig = crypt.SignStringENC(originalText)
outFile.WriteLine("Detached Signature:")
outFile.WriteLine(pkcs7sig)

'  This signature looks like this:
'  MIIG5wYJKoZIhvcNAQcCoIIG2DCCBtQCAQExDzANBgl .. YToLqEwTdU87ox5g7rvw==

'  The ASN.1 of the signature can be examined by browsing to https://lapo.it/asn1js/ ,
'  then copy-and-paste the Base64 signature into the form and decode..

'  The signature can be verified against the original data like this:
success = crypt.VerifyStringENC(originalText,pkcs7sig)
outFile.WriteLine("Signature verified: " & success)
success = crypt.VerifyStringENC("Not the original text",pkcs7sig)
outFile.WriteLine("Signature verified: " & success)

'  Now we'll create an opaque signature (the opposite of a detached signature). 
'  An opaque signature is a PKCS7 message that contains both the original data and
'  the signature.  The verification process extracts the original data.
opaqueSig = crypt.OpaqueSignStringENC(originalText)
outFile.WriteLine("Opaque Signature:")
outFile.WriteLine(opaqueSig)

'  The ASN.1 of the signature can be examined by browsing to https://lapo.it/asn1js/ ,
'  then copy-and-paste the Base64 signature into the form and decode..

'  We can verify and extract the original data:
origTxt = crypt.OpaqueVerifyStringENC(opaqueSig)
If (crypt.LastMethodSuccess <> 1) Then
    outFile.WriteLine("Signature verification failed.")
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Signature verified.")
outFile.WriteLine("Extracted text:" & origTxt)

outFile.Close