(VBScript) Extract PKCS7 Signature Digest

Demonstrates how to extract a signature digest from a PKCS7 signature.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat Crypt API to have been previously unlocked.
' See Unlock Chilkat Crypt for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

p7mFile = "qa_data/p7m/test.pdf.p7m"
outPath = "qa_output/test.pdf"

' First let's see if this .p7m signature can be verified, and the original file extracted.
verified = crypt.VerifyP7M(p7mFile,outPath)
If (verified <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' How many signers?
' (The NumSignerCerts property is set whenever a signature is verified.)
outFile.WriteLine("Num Signers: " & crypt.NumSignerCerts)

' Load the .p7m into memory...
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set pkcs7Data = CreateObject("Chilkat.BinData")
success = pkcs7Data.LoadFile(p7mFile)

' Check to see if this .p7m contains the binary bytes, or if it's
' already base64 encoded.  Get the 1st two bytes.  If the first two 
' bytes are the us-ascii values "MI", then we have base64.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbBase64 = CreateObject("Chilkat.StringBuilder")
hexStr = pkcs7Data.GetEncodedChunk(0,2,"hex")
success = sbBase64.Append(hexStr)

bHaveBase64 = 0
If (sbBase64.ContentsEqual("4D49",1) = 1) Then
    bHaveBase64 = 1
    sbBase64.Clear 
    success = sbBase64.AppendBd(pkcs7Data,"utf-8",0,0)
End If

' Get each signer's signature digest.
crypt.EncodingMode = "base64"
i = 0

Do While i < crypt.NumSignerCerts
    If (bHaveBase64) Then
        digest = crypt.Pkcs7ExtractDigest(i,sbBase64.GetAsString())
    Else
        digest = crypt.Pkcs7ExtractDigest(i,pkcs7Data.GetEncoded("base64"))
    End If

    If (crypt.LastMethodSuccess <> 1) Then
        outFile.WriteLine(crypt.LastErrorText)
        WScript.Quit
    End If

    outFile.WriteLine("Signer " & (i + 1) & " digest = " & digest)
    i = i + 1
Loop

outFile.Close