(VBScript) PKCS11 Generate a RSA Key that stays on the HSM

See more PKCS11 Examples

Generates an RSA key on the smart card or token and returns the public and private key handles. The generated RSA key stays on the HSM even after the PKCS11 session has ended.

Note: This example requires Chilkat v9.5.0.96 or later.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: Chilkat's PKCS11 implementation runs on Windows, Linux, Mac OS X, and other supported operating systems.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Pkcs11")
set pkcs11 = CreateObject("Chilkat.Pkcs11")

' Use the PKCS11 driver (.dll, .so, .dylib) for your particular HSM.
' (The format of the path will change with the operating system.  Obviously, "C:/" is not used on non-Windows systems.
pkcs11.SharedLibPath = "C:/Program Files (x86)/Gemalto/IDGo 800 PKCS#11/IDPrimePKCS1164.dll"

' Establish a logged-on session.
' Use your actual PIN here.
pin = "0000"
userType = 1
success = pkcs11.QuickSession(userType,pin)
If (success = 0) Then
    outFile.WriteLine(pkcs11.LastErrorText)
    WScript.Quit
End If

' Specify attributes and abilities (how this key can be used) by providing a JSON template.
' One template is for the public key, and the other for the private key.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set pubKeyAttr = CreateObject("Chilkat.JsonObject")

' Generate a RSA key that remains on the HSM by setting the "token" attribute equal to 1
success = pubKeyAttr.UpdateBool("token",1)

' Given that our key will reside on the token, we should give it two attributes (id and label) to help us
' find it in future sessions.

' First, we can give it an arbitrary ID.  ID's are binary, so we specify bytes as either 
' "id_hex" for hexidecimal bytes, 
' "id_ascii" for the bytes of an ascii string, 
' "id" for bytes in base64 format.
keyId = "48656C6C6F"
success = pubKeyAttr.UpdateString("id_hex",keyId)

' We can also give our key a label with any descriptive string.
keyLabel = "2048-bit RSA key for testing"
success = pubKeyAttr.UpdateString("label",keyLabel)

' -----------------------------------------------------------------------------------
' IMPORTANT: The ID for the public key must be the same as the ID for the private key.
' -----------------------------------------------------------------------------------

' Allow the public key to be used for encryption, signature verification, and symmetric key wrapping.
' These attributes are optional.
success = pubKeyAttr.UpdateBool("encrypt",1)
success = pubKeyAttr.UpdateBool("verify",1)
success = pubKeyAttr.UpdateBool("wrap",1)

' Generate a 2048-bit RSA key.
' This attribute is required.
success = pubKeyAttr.UpdateInt("modulus_bits",2048)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set privKeyAttr = CreateObject("Chilkat.JsonObject")

' Generate a RSA key that remains on the HSM by setting the "token" attribute equal to 1
success = privKeyAttr.UpdateBool("token",1)

' Make sure we give the private key the same ID as the public key.
success = privKeyAttr.UpdateString("id_hex",keyId)

' We can also give our key a label with any descriptive string.
' (Best to use the same label as for the public key)
success = privKeyAttr.UpdateString("label",keyLabel)

' Allow the private key to be used for signing and decryption.
success = privKeyAttr.UpdateBool("sign",1)
success = privKeyAttr.UpdateBool("decrypt",1)

' Provide a JSON object to receive the public and private key handles.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonHandles = CreateObject("Chilkat.JsonObject")
jsonHandles.EmitCompact = 0

' Provide a Chilkat public key object to receive the public key.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PublicKey")
set pubKey = CreateObject("Chilkat.PublicKey")

success = pkcs11.GenRsaKey(pubKeyAttr,privKeyAttr,jsonHandles,pubKey)
If (success = 0) Then
    outFile.WriteLine(pkcs11.LastErrorText)
    outFile.WriteLine("Failed to generate an RSA key.")
Else
    ' Sample JSON handles:
    ' {
    '   "public_key_handle": 18415630,
    '   "private_key_handle": 74842125
    ' }
    outFile.WriteLine(jsonHandles.Emit())
    outFile.WriteLine("public_key_handle: " & jsonHandles.UIntOf("public_key_handle"))
    outFile.WriteLine("private_key_handle: " & jsonHandles.UIntOf("private_key_handle"))
    outFile.WriteLine("public key JWK:")
    outFile.WriteLine(pubKey.GetJwk())
    ' Sample JWK:
    ' {"kty":"RSA","n":"1sQMSAntY80L .... If9jqfMp4omQ","e":"AQAB"}
    outFile.WriteLine("Success.")
End If

success = pkcs11.Logout()
success = pkcs11.CloseSession()

outFile.Close