(VBScript) Load P7B and Iterate Certificates

Demonstrates how to load a .p7b containing one or more certificates access each of them.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Starting in v9.5.0.49, all Chilkat classes can be unlocked at once at the beginning of a program
' by calling UnlockBundle.  It requires a Bundle unlock code.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Global")
set chilkatGlob = CreateObject("Chilkat.Global")
success = chilkatGlob.UnlockBundle("Anything for 30-day trial.")
If (success <> 1) Then
    outFile.WriteLine(chilkatGlob.LastErrorText)
    WScript.Quit
End If

' The Chilkat PEM class was introduced in v9.5.0.49.  
' It requires the bundle to be unlocked, as shown above.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Pem")
set pem = CreateObject("Chilkat.Pem")

' Load the .p7b from a file.
success = pem.LoadP7bFile("../myCertFiles/myP7b.p7b")
If (success <> 1) Then
    outFile.WriteLine(pem.LastErrorText)
    WScript.Quit
End If

' Note: If the app already has the p7b loaded in memory, the LoadP7b method
' may be called instead.  (see the online reference documentation)

' Iterate over the certificates.
numCerts = pem.NumCerts
i = 0

Do While i < numCerts

    ' cert is a Chilkat.Cert
    Set cert = pem.GetCert(i)
    outFile.WriteLine("Certificate " & i & " : " & cert.SubjectDN)

    i = i + 1
Loop

outFile.Close