(VBScript) Add Private Key and Certificate to a PEM

Demonstrates how to add certificates and private keys to a PEM.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The Chilkat PEM class was introduced in v9.5.0.49.  
' It requires the bundle to be unlocked, as shown above.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Pem")
set pem = CreateObject("Chilkat.Pem")

' Add the private key found in alice.key to this PEM.
' 
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set privKey = CreateObject("Chilkat.PrivateKey")

success = privKey.LoadAnyFormatFile("qa_data/alice.key","")
If (success <> 1) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

' Add it to the PEM:
success = pem.AddPrivateKey(privKey)

' Add the certificate found in alice.crt to this PEM.
' 
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")

success = cert.LoadFromFile("qa_data/alice.crt")
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Add it to the PEM:
includeCertChain = 0
success = pem.AddCert(cert,includeCertChain)

' Write the PEM containing the private key and certificate.
' The private key will be output in PKCS8 encrypted form.
' Certificates are never encrypted.

' This is the password that will be required to open and access the private key
' from the PEM we're about to write..
password = "secret"
extendedAttrs = 0
noKeys = 0
noCerts = 0
noCaCerts = 0
encryptAlg = "aes128"

pemStr = pem.ToPemEx(extendedAttrs,noKeys,noCerts,noCaCerts,encryptAlg,password)
outFile.WriteLine(pemStr)

outFile.Close