VBScript

Get PDF Signer Certs

See more PDF Signatures Examples

This example demonstrates how to validate the signatures in a PDF and also shows how to get VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set pdf = CreateObject("Chilkat.Pdf")

' Load a PDF that has cryptographic signatures to be validated
success = pdf.LoadFile("qa_data/pdf/sign_testing_1/helloSigned2.pdf")
If (success = 0) Then
    outFile.WriteLine(pdf.LastErrorText)
    WScript.Quit
End If

' Each time we verify a signature, information about the signature is written into
' sigInfo (replacing whatever sigInfo previously contained).
set sigInfo = CreateObject("Chilkat.JsonObject")

' Iterate over each signature and validate each.
numSignatures = pdf.NumSignatures
validated = 0
set cert = CreateObject("Chilkat.Cert")
i = 0
Do While i < numSignatures
    validated = pdf.VerifySignature(i,sigInfo)
    outFile.WriteLine("Signature " & i & " validated: " & validated)

    ' After calling VerifySignature, you can get the signer certificate by calling
    ' GetSignerCert with the same index. 
    success = pdf.GetSignerCert(i,cert)
    If (success <> 0) Then
        outFile.WriteLine("PDF signer certificate: " & cert.SubjectDN)
    End If

    i = i + 1
Loop

outFile.WriteLine("Finished.")

outFile.Close