(VBScript) Extract Embedded Files from PDF

Demonstrates how to get information about the embedded files (if any) contained within a PDF, and shows how to extract each file.

Note: This example requires Chilkat v9.5.0.95 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Pdf")
set pdf = CreateObject("Chilkat.Pdf")

success = pdf.LoadFile("qa_data/pdf/embedded_files/my_embedded_files_test.pdf")
If (success = 0) Then
    outFile.WriteLine(pdf.LastErrorText)
    WScript.Quit
End If

' Note: The embedded file functionality was added in Chilkat v9.5.0.95

' How many embedded files exist within the opened PDF?
numFiles = pdf.NumEmbeddedFiles
outFile.WriteLine("Number of embedded files: " & numFiles)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
json.EmitCompact = 0

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")

' Get information about each file, and extract each to the filesystem.
i = 0
Do While i < numFiles

    success = pdf.GetEmbeddedFileInfo(i,json)
    If (success = 0) Then
        outFile.WriteLine(pdf.LastErrorText)
        WScript.Quit
    End If

    outFile.WriteLine(json.Emit())

    ' Get the filename from the JSON.
    filename = "someFile.dat"

    ' The filename SHOULD always be present..
    If (json.HasMember("filename") = 1) Then
        filename = json.StringOf("filename")
    End If

    ' Get the file data.
    success = pdf.GetEmbeddedFileBd(i,bd)
    If (success = 0) Then
        outFile.WriteLine(pdf.LastErrorText)
        WScript.Quit
    End If

    ' Save the contents of the bd to the filename (in the current working directory) in the filesystem.
    success = bd.WriteFile(filename)
    If (success = 0) Then
        outFile.WriteLine("Failed to write output file.")
    End If

    i = i + 1
Loop

' Sample output for the above code:

' Number of embedded files: 3
' {
'   "filename": "employees.json",
'   "desc": "JSON",
'   "subType": "application/json",
'   "size": 159,
'   "creationDate": "D:20230715170506-05'00'",
'   "modDate": "D:20160207153838-05'00'"
' }
' 
' {
'   "filename": "rsaPubKey.pem",
'   "desc": "RSA Public Key PEM",
'   "size": 451,
'   "creationDate": "D:20230715170546-05'00'",
'   "modDate": "D:20150724133153-05'00'"
' }
' 
' {
'   "filename": "starfish.jpg",
'   "desc": "Starfish JPG",
'   "subType": "image/jpeg",
'   "size": 6229,
'   "creationDate": "D:20230715170356-05'00'",
'   "modDate": "D:20080529103055-05'00'"
' }

outFile.Close