(VBScript) Add a Document Timestamp Signature to an already-signed PDF

See more PDF Signatures Examples

Demonstrates how to add a document timestamp signature to an already-signed PDF.

Note: This example requires Chilkat v9.5.0.99 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Pdf")
set pdf = CreateObject("Chilkat.Pdf")

' Load the PDF that has already been signed.
success = pdf.LoadFile("qa_data/pdf/helloWorld_signed.pdf")
If (success = 0) Then
    outFile.WriteLine(pdf.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")

success = json.UpdateBool("invisibleSignature",1)
success = json.UpdateString("subFilter","/ETSI.RFC3161")

success = json.UpdateBool("timestampToken.enabled",1)

' In this example, we'll use a free TSA server (timestamp.digicert.com), but you may want to use your own timestamp authority server.
success = json.UpdateString("timestampToken.tsaUrl","http://timestamp.digicert.com")

' If the timestamp server requires a username/password, do the following.  Otherwise omit the following few lines of code.
success = json.UpdateString("timestampToken.tsaUsername","the_tsa_username")
success = json.UpdateString("timestampToken.tsaPassword","the_tsa_password")

' When requesting the timestamp token, ask the server to include its certificate in the timestamp token response.
' This allows for the timestamp server's certificate to be included in the LTV validation (i.e. if the timestamp server
' has an OCSP URL, then Chilkat will also do the OCSP request for the timestamp server's certificate.)
success = json.UpdateBool("timestampToken.requestTsaCert",1)

success = pdf.SignPdf(json,"c:/temp/qa_output/helloWorld_signed_2.pdf")
If (success = 0) Then
    outFile.WriteLine(pdf.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Successfully added a Document Timestamp Signature to the PDF")

outFile.Close