(VBScript) PC/SC Get Card UID

See more SCard Examples

Sends the APDU command to get a card's UID.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SCard")
set scard = CreateObject("Chilkat.SCard")

' First establish a context to the PC/SC Resource Manager
success = scard.EstablishContext("user")
If (success = 0) Then
    outFile.WriteLine(scard.LastErrorText)
    WScript.Quit
End If

' Use your own smart card reader name here.
success = scard.Connect("ACS ACR122 0","shared","no_preference")
If (success = 0) Then
    outFile.WriteLine(scard.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Connected reader: " & scard.ConnectedReader)
outFile.WriteLine("Active protocol: " & scard.ActiveProtocol)
outFile.WriteLine("ATR: " & scard.CardAtr)
outFile.WriteLine("Reader Status: " & scard.ReaderStatus)

'  Send the APDU command 0xFF, 0xCA, 0x00, 0x00, 0x00
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdRecv = CreateObject("Chilkat.BinData")
success = scard.TransmitHex(scard.ActiveProtocol,"FFCA000000",bdRecv,32)
If (success = 1) Then

    outFile.WriteLine("Received: " & bdRecv.GetEncoded("hex"))

    ' The UID is the returned data without the final 2 bytes.
    numBytes = bdRecv.NumBytes
    If (numBytes > 2) Then
        outFile.WriteLine("UID: " & bdRecv.GetEncodedChunk(0,numBytes - 2,"hex"))
    End If

Else
    outFile.WriteLine(scard.LastErrorText)
End If

' Disconnect from this reader.
success = scard.Disconnect("leave")
If (success = 0) Then
    outFile.WriteLine(scard.LastErrorText)
End If

' Applications should always release the context when finished.
success = scard.ReleaseContext()
If (success = 0) Then
    outFile.WriteLine(scard.LastErrorText)
End If


outFile.Close