(VBScript) PC/SC Check the Status of each Smart Card Reader (and USB token)

See more SCard Examples

Demonstrates how to list the smart card readers and USB tokens connected to the computer, and check the status of each.

Note: This functionality was introduced in Chilkat v9.5.0.87.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SCard")
set scard = CreateObject("Chilkat.SCard")

' First establish a context to the PC/SC Resource Manager
success = scard.EstablishContext("user")
If (success = 0) Then
    outFile.WriteLine(scard.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringTable")
set stReaders = CreateObject("Chilkat.StringTable")
success = scard.ListReaders(stReaders)
If (success = 0) Then
    outFile.WriteLine(scard.LastErrorText)
    WScript.Quit
End If

numReaders = stReaders.Count
i = 0
Do While i < numReaders
    reader = stReaders.StringAt(i)

    outFile.WriteLine(i & ": " & reader)

    ' Connect to this reader.
    If (scard.Connect(reader,"shared","no_preference") = 1) Then

        ' Check the status to get the reader state, active protocol, and card ATR (if a card is inserted).
        If (scard.CheckStatus() = 1) Then
            outFile.WriteLine("ReaderStatus: " & scard.ReaderStatus)
            outFile.WriteLine("CardAtr: " & scard.CardAtr)
            outFile.WriteLine("ActiveProtocol: " & scard.ActiveProtocol)
        Else
            outFile.WriteLine(scard.LastErrorText)
            outFile.WriteLine("CheckStatus failed.")
        End If

        ' Disconnect from this reader.
        success = scard.Disconnect("leave")
    Else
        outFile.WriteLine(scard.LastErrorText)
        outFile.WriteLine("Connect failed.")
    End If

    outFile.WriteLine("---------------------------------------")
    i = i + 1
Loop

' Sample output:

' 0: Alcor Micro USB Smart Card Reader 0
' ReaderStatus: specific
' CardAtr: 3B7F96000080318065B0855956FB120FFE829000
' ActiveProtocol: T0
' ---------------------------------------
' 1: Generic Smart Card Reader Interface 0
' ReaderStatus: specific
' CardAtr: 3BFC180000813180459067464A00641606F2727E00E0
' ActiveProtocol: T1
' ---------------------------------------
' 2: SCM Microsystems Inc. SCR33x USB Smart Card Reader 0
' ReaderStatus: specific
' CardAtr: 3BDF96FF8131FE455A018048494443313158587300011B09
' ActiveProtocol: T1
' ---------------------------------------

' Applications should always release the context when finished.
success = scard.ReleaseContext()
If (success = 0) Then
    outFile.WriteLine(scard.LastErrorText)
End If


outFile.Close