(VBScript) PayPal - Show Invoice Details

Shows details for a PayPal invoice, by ID.

See also PayPal Show Invoice Details REST API Reference

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Note: Requires Chilkat v9.5.0.64 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load our previously obtained access token. (see PayPal OAuth2 Access Token)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/paypal.json")

' Build the Authorization request header field value.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbAuth = CreateObject("Chilkat.StringBuilder")
' token_type should be "Bearer"
success = sbAuth.Append(jsonToken.StringOf("token_type"))
success = sbAuth.Append(" ")
success = sbAuth.Append(jsonToken.StringOf("access_token"))

' Make the initial connection.
' A single REST object, once connected, can be used for many PayPal REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")
bAutoReconnect = 1
success = rest.Connect("api.sandbox.paypal.com",443,1,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

success = rest.AddHeader("Authorization",sbAuth.GetAsString())

invoiceId = "INV2-XV4B-736P-PLVN-SZCE"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbPath = CreateObject("Chilkat.StringBuilder")
success = sbPath.Append("/v1/invoicing/invoices/")
success = sbPath.Append(invoiceId)

' Send the GET request and get the JSON response.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbJsonResponse = CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestNoBodySb("GET",sbPath.GetAsString(),sbJsonResponse)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
json.EmitCompact = 0
success = json.LoadSb(sbJsonResponse)

outFile.WriteLine("Response Status Code = " & rest.ResponseStatusCode)

' Did we get a 200 success response?
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine(json.Emit())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' Sample response JSON is shown below.

' Get some information..
outFile.WriteLine("email: " & json.StringOf("merchant_info.email"))
outFile.WriteLine("business_name: " & json.StringOf("merchant_info.business_name"))

numItems = json.SizeOfArray("items")
i = 0
Do While i < numItems
    json.I = i
    outFile.WriteLine("item name: " & json.StringOf("items[i].name"))
    outFile.WriteLine("item quantity: " & json.StringOf("items[i].quantity"))
    outFile.WriteLine("item currency: " & json.StringOf("items[i].unit_price.currency"))
    outFile.WriteLine("item value: " & json.StringOf("items[i].unit_price.value"))
    outFile.WriteLine("----")
    i = i + 1
Loop

outFile.WriteLine("Success.")

' ---------------------------------------------------
' A sample response:

' 	{
' 	  "id": "INV2-XV4B-736P-PLVN-SZCE",
' 	  "number": "0002",
' 	  "template_id": "TEMP-8HS37702UW384535K",
' 	  "status": "DRAFT",
' 	  "merchant_info": {
' 	    "email": "smith-facilitator@chilkatsoft.com",
' 	    "first_name": "Joe",
' 	    "last_name": "Facilitator",
' 	    "business_name": "Medical Professionals, LLC",
' 	    "phone": {
' 	      "country_code": "001",
' 	      "national_number": "5032141716"
' 	    },
' 	    "address": {
' 	      "line1": "1234 Main St.",
' 	      "city": "Portland",
' 	      "state": "OR",
' 	      "postal_code": "97217",
' 	      "country_code": "US"
' 	    }
' 	  },
' 	  "billing_info": [
' 	    {
' 	      "email": "smith-buyer@chilkatsoft.com"
' 	    }
' 	  ],
' 	  "shipping_info": {
' 	    "first_name": "Sally",
' 	    "last_name": "Patient",
' 	    "business_name": "Not applicable",
' 	    "phone": {
' 	      "country_code": "001",
' 	      "national_number": "5039871234"
' 	    },
' 	    "address": {
' 	      "line1": "1234 Broad St.",
' 	      "city": "Portland",
' 	      "state": "OR",
' 	      "postal_code": "97216",
' 	      "country_code": "US"
' 	    }
' 	  },
' 	  "items": [
' 	    {
' 	      "name": "Sutures",
' 	      "quantity": 100.0,
' 	      "unit_price": {
' 	        "currency": "USD",
' 	        "value": "5.00"
' 	      }
' 	    }
' 	  ],
' 	  "invoice_date": "2016-11-15 PST",
' 	  "payment_term": {
' 	    "term_type": "NET_45",
' 	    "due_date": "2016-12-30 PST"
' 	  },
' 	  "tax_calculated_after_discount": false,
' 	  "tax_inclusive": false,
' 	  "note": "Medical Invoice 16 Jul, 2013 PST",
' 	  "total_amount": {
' 	    "currency": "USD",
' 	    "value": "500.00"
' 	  },
' 	  "metadata": {
' 	    "created_date": "2016-11-15 08:09:21 PST"
' 	  },
' 	  "links": [
' 	    {
' 	      "rel": "self",
' 	      "href": "https://api.sandbox.paypal.com/v1/invoicing/invoices/INV2-XV4B-736P-PLVN-SZCE",
' 	      "method": "GET"
' 	    },
' 	    {
' 	      "rel": "send",
' 	      "href": "https://api.sandbox.paypal.com/v1/invoicing/invoices/INV2-XV4B-736P-PLVN-SZCE/send",
' 	      "method": "POST"
' 	    },
' 	    {
' 	      "rel": "update",
' 	      "href": "https://api.sandbox.paypal.com/v1/invoicing/invoices/INV2-XV4B-736P-PLVN-SZCE/update",
' 	      "method": "PUT"
' 	    },
' 	    {
' 	      "rel": "delete",
' 	      "href": "https://api.sandbox.paypal.com/v1/invoicing/invoices/INV2-XV4B-736P-PLVN-SZCE",
' 	      "method": "DELETE"
' 	    }
' 	  ]
' 	}
' 

outFile.Close