VBScript

PayPal Send Invoice

See more PayPal Examples

Sends a PayPal invoice to a customer.

See also Send Invoice

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Note: Requires Chilkat v9.5.0.64 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load our previously obtained access token. (see PayPal OAuth2 Access Token)
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/paypal.json")

' Build the Authorization request header field value.
set sbAuth = CreateObject("Chilkat.StringBuilder")
' token_type should be "Bearer"
success = sbAuth.Append(jsonToken.StringOf("token_type"))
success = sbAuth.Append(" ")
success = sbAuth.Append(jsonToken.StringOf("access_token"))

' Make the initial connection.
' A single REST object, once connected, can be used for many PayPal REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
set rest = CreateObject("Chilkat.Rest")
bAutoReconnect = 1
success = rest.Connect("api.sandbox.paypal.com",443,1,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

' Build a path using a draft invoice ID.
set sbPath = CreateObject("Chilkat.StringBuilder")
success = sbPath.Append("/v1/invoicing/invoices/invoice_id/send")
numReplacements = sbPath.Replace("invoice_id","INV2-QCHR-QHSD-M2VU-AVXC")

success = rest.AddHeader("Authorization",sbAuth.GetAsString())
success = rest.AddQueryParam("notify_merchant","true")

responseBody = rest.FullRequestFormUrlEncoded("POST",sbPath.GetAsString())
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response Status Code = " & rest.ResponseStatusCode)

' Did we get a 202 accepted response?
If (rest.ResponseStatusCode <> 202) Then
    outFile.WriteLine(responseBody)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' If the 202 response is received, the response body would be empty...
outFile.WriteLine("Success.")

outFile.Close