VBScript
PayPal Generate QR Code

Generates a QR code for an invoice, by ID.
The QR code is a PNG image in Base64-encoded format that corresponds to the invoice ID.
Note: A QR code can only be generated for an invoice that has been both created and sent.
Chilkat VBScript Downloads

VBScript
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Note: Requires Chilkat v9.5.0.64 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load our previously obtained access token. (see PayPal OAuth2 Access Token)
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/paypal.json")

' Build the Authorization request header field value.
set sbAuth = CreateObject("Chilkat.StringBuilder")
' token_type should be "Bearer"
success = sbAuth.Append(jsonToken.StringOf("token_type"))
success = sbAuth.Append(" ")
success = sbAuth.Append(jsonToken.StringOf("access_token"))

' Make the initial connection.
' A single REST object, once connected, can be used for many PayPal REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
set rest = CreateObject("Chilkat.Rest")
bAutoReconnect = 1
success = rest.Connect("api.sandbox.paypal.com",443,1,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

' Build a path using an invoice ID.
set sbPath = CreateObject("Chilkat.StringBuilder")
success = sbPath.Append("/v1/invoicing/invoices/invoice_id/qr-code")
numReplacements = sbPath.Replace("invoice_id","INV2-ZG2H-HKAW-PMWU-N6ZR")

success = rest.AddHeader("Authorization",sbAuth.GetAsString())
' A 500x500 image results in a PNG file of approx. 4K bytes in size.
success = rest.AddQueryParam("width","500")
success = rest.AddQueryParam("height","500")
success = rest.AddQueryParam("action","pay")

' Send the GET request and get the PNG image data as base64.
' A successful JSON response looks like this:
' {"image":"iVBORw0KGgoAA....AASUVORK5CYII="}
set sbJsonResponse = CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestNoBodySb("GET",sbPath.GetAsString(),sbJsonResponse)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

set json = CreateObject("Chilkat.JsonObject")
json.EmitCompact = 0
success = json.LoadSb(sbJsonResponse)

outFile.WriteLine("Response Status Code = " & rest.ResponseStatusCode)

' Did we get a 200 success response?
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine(json.Emit())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' If the 200 response is received, the response body contains the PNG data.
' Save the PNG to a file.
set pngData = CreateObject("Chilkat.BinData")
success = pngData.AppendEncoded(json.StringOf("image"),"base64")
success = pngData.WriteFile("qa_output/paypal_qr_code.png")
If (success = 0) Then
    outFile.WriteLine("Failed to save PNG file.")
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close