(VBScript) PayPal - Create Stored Credit Card Payment

Creates a credit card payment using a card ID from a previously stored credit card (where the credit card was stored in PayPal's vault).

Note: For sandbox calls, you can use the credit card numbers provided in your sandbox test accounts.

Note: This example requires Chilkat v9.5.0.65 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Note: Requires Chilkat v9.5.0.65 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load our previously obtained access token. (see PayPal OAuth2 Access Token)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/paypal.json")

' Build the Authorization request header field value.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbAuth = CreateObject("Chilkat.StringBuilder")
' token_type should be "Bearer"
success = sbAuth.Append(jsonToken.StringOf("token_type"))
success = sbAuth.Append(" ")
success = sbAuth.Append(jsonToken.StringOf("access_token"))

' Make the initial connection.
' A single REST object, once connected, can be used for many PayPal REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")
bAutoReconnect = 1
success = rest.Connect("api.sandbox.paypal.com",443,1,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

' We previously stored the user's credit card data in PayPal's vault.
' See Store Card in PayPal Vault for sample code.

' Build the JSON containing the stored credit card information and transaction information.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
json.EmitCompact = 0
success = json.UpdateString("intent","sale")
success = json.UpdateString("payer.payment_method","credit_card")
success = json.UpdateString("payer.funding_instruments[0].credit_card_token.credit_card_id","CARD-52W84623JH8043102LA3CLGA")
success = json.UpdateString("payer.funding_instruments[0].credit_card_token.payer_id","user12345")
success = json.UpdateString("transactions[0].amount.total","6.70")
success = json.UpdateString("transactions[0].amount.currency","USD")
success = json.UpdateString("transactions[0].description","This is the payment transaction description.")

outFile.WriteLine(json.Emit())

' The JSON created by the above code is this:

' 	{ 
' 	  "intent": "sale",
' 	  "payer": { 
' 	    "payment_method": "credit_card",
' 	    "funding_instruments": [
' 	      { 
' 	        "credit_card_token": { 
' 	          "credit_card_id": "CARD-52W84623JH8043102LA3CLGA",
' 	          "payer_id": "user12345"
' 	        }
' 	      }
' 	    ]
' 	  },
' 	  "transactions": [
' 	    { 
' 	      "amount": { 
' 	        "total": "6.70",
' 	        "currency": "USD"
' 	      },
' 	      "description": "This is the payment transaction description."
' 	    }
' 	  ]
' 	}

success = rest.AddHeader("Authorization",sbAuth.GetAsString())
success = rest.AddHeader("Content-Type","application/json")

' Send the POST request containign the JSON in the request body, and get the JSON response.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbJsonRequest = CreateObject("Chilkat.StringBuilder")
json.EmitCompact = 1
success = json.EmitSb(sbJsonRequest)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbJsonResponse = CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestSb("POST","/v1/payments/payment",sbJsonRequest,sbJsonResponse)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

json.EmitCompact = 0
success = json.LoadSb(sbJsonResponse)

outFile.WriteLine("Response Status Code = " & rest.ResponseStatusCode)

' Did we get a 201 success response?
If (rest.ResponseStatusCode <> 201) Then
    outFile.WriteLine(json.Emit())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' Sample JSON response is shown below.
outFile.WriteLine(json.Emit())

' Demonstrate how to access a few parts of the JSON response..
outFile.WriteLine("credit_card_id: " & json.StringOf("payer.funding_instruments[0].credit_card_token.credit_card_id"))
outFile.WriteLine("subtotal: " & json.StringOf("transactions[0].amount.details.subtotal"))
outFile.WriteLine("refund href: " & json.StringOf("transactions[0].related_resources[0].sale.links[1].href"))
outFile.WriteLine("success")

' ------------------------------------------------
' A sample JSON response:

' 	{ 
' 	  "id": "PAY-12T35751GS725073SLA3CQNQ",
' 	  "create_time": "2016-11-23T23:37:26Z",
' 	  "update_time": "2016-11-23T23:37:31Z",
' 	  "state": "approved",
' 	  "intent": "sale",
' 	  "payer": { 
' 	    "payment_method": "credit_card",
' 	    "funding_instruments": [
' 	      { 
' 	        "credit_card_token": { 
' 	          "credit_card_id": "CARD-52W84623JH8043102LA3CLGA",
' 	          "payer_id": "user12345",
' 	          "last4": "9974",
' 	          "type": "visa",
' 	          "expire_month": "9",
' 	          "expire_year": "2021"
' 	        }
' 	      }
' 	    ]
' 	  },
' 	  "transactions": [
' 	    { 
' 	      "amount": { 
' 	        "total": "6.70",
' 	        "currency": "USD",
' 	        "details": { 
' 	          "subtotal": "6.70"
' 	        }
' 	      },
' 	      "description": "This is the payment transaction description.",
' 	      "related_resources": [
' 	        { 
' 	          "sale": { 
' 	            "id": "4F194018A1618453G",
' 	            "create_time": "2016-11-23T23:37:26Z",
' 	            "update_time": "2016-11-23T23:37:31Z",
' 	            "amount": { 
' 	              "total": "6.70",
' 	              "currency": "USD"
' 	            },
' 	            "state": "completed",
' 	            "parent_payment": "PAY-12T35751GS725073SLA3CQNQ",
' 	            "links": [
' 	              { 
' 	                "href": "https://api.sandbox.paypal.com/v1/payments/sale/4F194018A1618453G",
' 	                "rel": "self",
' 	                "method": "GET"
' 	              },
' 	              { 
' 	                "href": "https://api.sandbox.paypal.com/v1/payments/sale/4F194018A1618453G/refund",
' 	                "rel": "refund",
' 	                "method": "POST"
' 	              },
' 	              { 
' 	                "href": "https://api.sandbox.paypal.com/v1/payments/payment/PAY-12T35751GS725073SLA3CQNQ",
' 	                "rel": "parent_payment",
' 	                "method": "GET"
' 	              }
' 	            ],
' 	            "fmf_details": {},
' 	            "processor_response": { 
' 	              "avs_code": "X",
' 	              "cvv_code": "M"
' 	            }
' 	          }
' 	        }
' 	      ]
' 	    }
' 	  ],
' 	  "links": [
' 	    { 
' 	      "href": "https://api.sandbox.paypal.com/v1/payments/payment/PAY-12T35751GS725073SLA3CQNQ",
' 	      "rel": "self",
' 	      "method": "GET"
' 	    }
' 	  ]
' 	}
' 

outFile.Close