(VBScript) PayPal - Create a PayPal Payment

See more PayPal Examples

Creates a payment to be paid from a PayPal account (as opposed to being funded by a credit card).

Note: This example requires Chilkat v9.5.0.65 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Note: Requires Chilkat v9.5.0.65 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load our previously obtained access token. (see PayPal OAuth2 Access Token)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/paypal.json")

' Build the Authorization request header field value.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbAuth = CreateObject("Chilkat.StringBuilder")
' token_type should be "Bearer"
success = sbAuth.Append(jsonToken.StringOf("token_type"))
success = sbAuth.Append(" ")
success = sbAuth.Append(jsonToken.StringOf("access_token"))

' Make the initial connection.
' A single REST object, once connected, can be used for many PayPal REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")
bAutoReconnect = 1
success = rest.Connect("api.sandbox.paypal.com",443,1,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

' Build the JSON containing the transaction information.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
json.EmitCompact = 0
success = json.UpdateString("intent","sale")
success = json.UpdateString("redirect_urls.return_url","http://www.example.com/return_url")
success = json.UpdateString("redirect_urls.cancel_url","http://www.example.com/cancel_url")
success = json.UpdateString("payer.payment_method","paypal")
success = json.UpdateString("transactions[0].amount.total","7.47")
success = json.UpdateString("transactions[0].amount.currency","USD")
success = json.UpdateString("transactions[0].description","This is the payment transaction description.")

outFile.WriteLine(json.Emit())

' The JSON created by the above code is this:

' 	{ 
' 	  "intent": "sale",
' 	  "redirect_urls": { 
' 	    "return_url": "http://www.example.com/return_url",
' 	    "cancel_url": "http://www.example.com/cancel_url"
' 	  },
' 	  "payer": { 
' 	    "payment_method": "paypal"
' 	  },
' 	  "transactions": [
' 	    { 
' 	      "amount": { 
' 	        "total": "7.47",
' 	        "currency": "USD"
' 	      },
' 	      "description": "This is the payment transaction description."
' 	    }
' 	  ]
' 	}

success = rest.AddHeader("Authorization",sbAuth.GetAsString())
success = rest.AddHeader("Content-Type","application/json")

' Send the POST request containign the JSON in the request body, and get the JSON response.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbJsonRequest = CreateObject("Chilkat.StringBuilder")
json.EmitCompact = 1
success = json.EmitSb(sbJsonRequest)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbJsonResponse = CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestSb("POST","/v1/payments/payment",sbJsonRequest,sbJsonResponse)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

json.EmitCompact = 0
success = json.LoadSb(sbJsonResponse)

outFile.WriteLine("Response Status Code = " & rest.ResponseStatusCode)

' Did we get a 201 success response?
If (rest.ResponseStatusCode <> 201) Then
    outFile.WriteLine(json.Emit())
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' Sample JSON response is shown below.
outFile.WriteLine(json.Emit())
outFile.WriteLine("success")

' ------------------------------------------------
' A sample JSON response:

' 	{ 
' 	  "id": "PAY-1XK50350XV338620BLA3CZGI",
' 	  "intent": "sale",
' 	  "state": "created",
' 	  "payer": { 
' 	    "payment_method": "paypal",
' 	    "use_vendor_currency_conversion": false
' 	  },
' 	  "transactions": [
' 	    { 
' 	      "amount": { 
' 	        "total": "7.47",
' 	        "currency": "USD"
' 	      },
' 	      "description": "This is the payment transaction description.",
' 	      "related_resources": [
' 	      ]
' 	    }
' 	  ],
' 	  "create_time": "2016-11-23T23:56:09Z",
' 	  "links": [
' 	    { 
' 	      "href": "https://api.sandbox.paypal.com/v1/payments/payment/PAY-1XK50350XV338620BLA3CZGI",
' 	      "rel": "self",
' 	      "method": "GET"
' 	    },
' 	    { 
' 	      "href": "https://www.sandbox.paypal.com/cgi-bin/webscr?cmd=_express-checkout&token=EC-0BG932459F977083J",
' 	      "rel": "approval_url",
' 	      "method": "REDIRECT"
' 	    },
' 	    { 
' 	      "href": "https://api.sandbox.paypal.com/v1/payments/payment/PAY-1XK50350XV338620BLA3CZGI/execute",
' 	      "rel": "execute",
' 	      "method": "POST"
' 	    }
' 	  ]
' 	}

outFile.Close