(VBScript) Parse a Microsoft JSON Date (MS AJAX Date)

Demonstrates how to parse a Microsoft JSON Date, also known as an MSAJAX date.

Note: This example requires Chilkat v9.5.0.76 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Note: This example requires Chilkat v9.5.0.76 or greater.
' The ability to automatically parse Microsoft JSON Dates (AJAX Dates) was added in v9.5.0.76
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")

success = json.Load("{ ""AchievementDate"":""/Date(1540229468330-0500)/""}")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set dt = CreateObject("Chilkat.CkDateTime")
success = json.DateOf("AchievementDate",dt)
If (success <> 1) Then
    outFile.WriteLine("Unable to parse a date/time.")
    WScript.Quit
End If

' Show the date in different formats:
bLocal = 1
outFile.WriteLine("RFC822: " & dt.GetAsRfc822(bLocal))
outFile.WriteLine("Timestamp: " & dt.GetAsTimestamp(bLocal))
outFile.WriteLine("YYYY-MM-DD: " & dt.GetAsIso8601("YYYY-MM-DD",bLocal))

' Get integer values for year, month, day, etc.
' dtObj is a Chilkat.DtObj
Set dtObj = dt.GetDtObj(bLocal)
outFile.WriteLine("year: " & dtObj.Year)
outFile.WriteLine("month: " & dtObj.Month)
outFile.WriteLine("day: " & dtObj.Day)
outFile.WriteLine("hour: " & dtObj.Hour)
outFile.WriteLine("minute: " & dtObj.Minute)
outFile.WriteLine("seconds: " & dtObj.Second)

' Sample output:
' RFC822: Mon, 22 Oct 2018 17:31:08 -0500
' Timestamp: 2018-10-22T17:31:08-05:00
' YYYY-MM-DD: 2018-10-22
' year: 2018
' month: 10
' day: 22
' hour: 17
' minute: 31
' seconds: 8

outFile.Close