(VBScript) palena.sii.cl getSeed SOAP Request

Demonstrates how to call getSeed SOAP request at palena.sii.cl

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

http.UncommonOptions = "AllowEmptyHeaders"
http.SetRequestHeader "SOAPAction",""

http.SetRequestHeader "Content-Type","text/xml; charset=utf-8"

' The endpoint for this soap service is:
endPoint = "https://palena.sii.cl/DTEWS/CrSeed.jws"

' Send the following SOAP XML
' <soapenv:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:def="http://DefaultNamespace">
'    <soapenv:Header/>
'    <soapenv:Body>
'       <def:getSeed soapenv:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/"/>
'    </soapenv:Body>
' </soapenv:Envelope>

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "soapenv:Envelope"
success = xml.AddAttribute("xmlns:xsi","http://www.w3.org/2001/XMLSchema-instance")
success = xml.AddAttribute("xmlns:xsd","http://www.w3.org/2001/XMLSchema")
success = xml.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
success = xml.AddAttribute("xmlns:def","http://DefaultNamespace")
xml.UpdateChildContent "soapenv:Header",""
success = xml.UpdateAttrAt("soapenv:Body|def:getSeed",1,"soapenv:encodingStyle","http://schemas.xmlsoap.org/soap/encoding/")

' resp is a Chilkat.HttpResponse
Set resp = http.PostXml(endPoint,xml.GetXml(),"utf-8")
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    outFile.WriteLine("LastHeader:")
    outFile.WriteLine(http.LastHeader)
    WScript.Quit
End If

responseStatusCode = resp.StatusCode

outFile.WriteLine("Response Status Code: " & responseStatusCode)

' You may examine the exact HTTP header sent with the POST like this:
outFile.WriteLine("LastHeader:")
outFile.WriteLine(http.LastHeader)

' Examine the XML returned by the web service:
outFile.WriteLine("XML Response:")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xmlResp = CreateObject("Chilkat.Xml")
success = xmlResp.LoadXml(resp.BodyStr)
outFile.WriteLine(xmlResp.GetXml())

' Use this online tool to generate parsing code from response XML: 
' Generate Parsing Code from XML

' The response is:

' <?xml version="1.0" encoding="UTF-8"?>
' <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
'     <soapenv:Body>
'         <ns1:getSeedResponse soapenv:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/" xmlns:ns1="http://DefaultNamespace">
'             <ns1:getSeedReturn xsi:type="xsd:string">&lt;?xml version=&quot;1.0&quot; encoding=&quot;UTF-8&quot;?&gt;&lt;SII:RESPUESTA xmlns:SII=&quot;http://www.sii.cl/XMLSchema&quot;&gt;&lt;SII:RESP_BODY&gt;&lt;SEMILLA&gt;039159253918&lt;/SEMILLA&gt;&lt;/SII:RESP_BODY&gt;&lt;SII:RESP_HDR&gt;&lt;ESTADO&gt;00&lt;/ESTADO&gt;&lt;/SII:RESP_HDR&gt;&lt;/SII:RESPUESTA&gt;</ns1:getSeedReturn>
'         </ns1:getSeedResponse>
'     </soapenv:Body>
' </soapenv:Envelope>

' Get the XML contained in the getSeedReturn element:
embeddedXml = xmlResp.GetChildContent("soapenv:Body|ns1:getSeedResponse|ns1:getSeedReturn")
outFile.WriteLine(embeddedXml)

' The embedded XML is:

' <?xml version="1.0" encoding="UTF-8"?>
' <SII:RESPUESTA xmlns:SII="http://www.sii.cl/XMLSchema">
'     <SII:RESP_BODY>
'         <SEMILLA>039159397998</SEMILLA>
'     </SII:RESP_BODY>
'     <SII:RESP_HDR>
'         <ESTADO>00</ESTADO>
'     </SII:RESP_HDR>
' </SII:RESPUESTA>

' Get the seed:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml2 = CreateObject("Chilkat.Xml")
success = xml2.LoadXml(embeddedXml)
seed = xml2.GetChildContent("SII:RESP_BODY|SEMILLA")
outFile.WriteLine("seed =  " & seed)

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

outFile.Close