(VBScript) Duplicate openssl rsautl -verify -inkey pubKey.pem -pubin -in rsautl.sig -out originalFile.dat

Demonstrates how to duplicate this OpenSSL command:

openssl rsautl -verify -inkey pubKey.pem -pubin -in rsautl.sig -out originalFile.dat

The openssl rsautl command signs the data directly, and therefore the maximum amount of data that can signed is very small. (To sign any amount of data, use openssl dgst -sign.) The maximum amount of data that can be signed (with rsautl) is the key size minus the overhead for the padding. The overhead size depends on the padding. With OAEP padding, the overhead is 42 bytes. With the default PKCSv1.5 padding, the overhead is 11 bytes.

Given a 2048-bit RSA key (256 bytes) and using PKCSv1.5 padding, the max data size that can be signed is 256 - 11 = 245 bytes.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)



set pubKey = CreateObject("Chilkat_9_5_0.PublicKey")

'  Load the public key from an PEM file:
success = pubKey.LoadOpenSslPemFile("pubKey.pem")
If (success <> 1) Then
    outFile.WriteLine(pubKey.LastErrorText)
    WScript.Quit
End If

set fac = CreateObject("Chilkat_9_5_0.FileAccess")

'  Load the signature.
sigData = fac.ReadEntireFile("rsautl.sig")

set rsa = CreateObject("Chilkat_9_5_0.Rsa")

'  Any string argument automatically begins the 30-day trial.
success = rsa.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

'  Import the public key into the RSA component:
success = rsa.ImportPublicKeyObj(pubKey)
If (success <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

'  OpenSSL uses big-endian.
rsa.LittleEndian = 0

origData = rsa.OpenSslVerifyBytes(sigData)
If (rsa.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    outFile.WriteLine("The signature was invalid.")
    WScript.Quit
End If

outFile.WriteLine("The signature was verified.")

'  Save the original data that was extracted from the signature:
success = fac.WriteEntireFile("originalFile.dat",origData)
If (success <> 1) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If


outFile.Close