(VBScript) Encrypt with Chilkat, Decrypt with OpenSSL

Demonstrates how to RSA encrypt a string using Chilkat, and then shows the corresponding OpenSSL command to RSA decrypt. The OpenSSL command to decrypt is as follows:

openssl rsautl -decrypt -inkey VP_Private.pem -in rsa_encrypted.bin -out original.txt

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = CreateObject("Chilkat.Rsa")

' Note: RSA encryption uses the public key.  
' RSA decryption uses the private key.
' The reason is that the public key can be freely provided to anybody.  This allows anybody
' to send an encrypted message to the private key owner, and only the private key owner 
' can decrypt.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PublicKey")
set key = CreateObject("Chilkat.PublicKey")

' Load an RSA public key from a PEM file:
success = key.LoadFromFile("qa_data/pem/VP_Public.pem")
If (success <> 1) Then
    outFile.WriteLine(key.LastErrorText)
    WScript.Quit
End If

' Load the public key into the RSA object.
success = rsa.ImportPublicKeyObj(key)
If (success <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

strToEncrypt = "00000000;XYZ2-3BHQ-ABCD-MMVV;6MY1-GHJK-9LRR;0"

' The LittleEndian property is 0 by default, but it is set here
' anyway to show that LittleEndian byte ordering is required for OpenSSL compatibility.
rsa.LittleEndian = 0

usePrivateKey = 0

encryptedBytes = rsa.EncryptString(strToEncrypt,usePrivateKey)
If (rsa.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' The OpenSSL command to decrypt would be this:
' openssl rsautl -decrypt -inkey VP_Private.pem -in rsa_encrypted.bin -out original.txt

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")
success = fac.WriteEntireFile("qa_output/rsa_encrypted.bin",encryptedBytes)
If (success <> 1) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("RSA Encryption Succeeded.")

outFile.Close